Vertical to horizontal data with summing

[Sathish_jammy]

Dear Experts,

I want to visualize my data as a horizontal format with summing the year value.

 For example : 

data lkj;
input ID yearof;
cards;
132 2004
132 2004
132 2005
321 2010
321 2010
321 2015
run;

Required OP

ID	2004	2005	2010	2015
132	2	1	.	.
321	.	.	2	1

Kindly help me to transform in the given format.

Thanks in advance!

[PaigeMiller · Accepted solution]

proc report data=lkj;
    columns id yearof;
	define id/group;
	define yearof/across;
run;

By the way, this is counting, not summing.

[Sathish_jammy]

Thank you for your support! @PaigeMiller @Ksharp @PeterClemmensen 

All your suggestion works well.

[PeterClemmensen]

proc sql;
    create table temp as
    select *,
           count(*) as count
    from lkj
    group by ID, yearof;
quit;

proc transpose data=temp out=want(drop=_NAME_) prefix=_;
    by ID;
    id yearof;
    var count;
run;

[Ksharp]

It is best tool for PROC TABULATE.

data lkj;
input ID yearof;
cards;
132 2004
132 2004
132 2005
321 2010
321 2010
321 2015
;
proc tabulate data=lkj;
class id yearof;
table id,yearof*n=' '*f=best.;
run;