If the dates are a sparsely spaced as in your example, then for each record you're looking for 30 dates just to harvest 2 or 3 for SIN30.
If it weren't for memory problems, you could just make the hash an ordered hash (by id date), and associate a hash iterator with it. Then you could use the SETCUR method to get the current date and SIN. Then a sequence of NEXT methods to get successive observations until you bypass DATE30. This way there is no excess of unsatisfied FIND methods.
As to memory issues, you probably could populate the hash one ID at a time, process all the records for that id, and then clear the hash object in preparation for the next id. In that case you could just use DATE as the hash key.
However, the program below is almost certainly faster, as it uses an array (less memory overhead than hash), and since the array is accessed for N=1, 2, ..., it is a key-indexed array providing faster lookup than hash:
data want;
array _dat{100} ;
array _sin{100} ;
do _n=1 by 1 until (last.id);
set have;
by id;
_dat{_n}=date;
_sin{_n}=sin;
end;
do _n2=1 to _n;
set have;
sin30=0;
do _n3=_n2 to _n while (_dat{_n3}<=date30);
if _dat{_n3}>date30 then leave;
else sin30=sin30 + _sin{_n3};
end;
output;
end;
drop _: ;
run;
This program assumes no ID has more than 100 dates. If that's not true, just set the dimension of arrays _dat and _sin to exceed the maximum expected date count.
The program reads a single ID once to populate the arrays. Then it re-reads the same ID, and retrieves data from the array as needed. This type of re-read is probably relatively efficient, since the re-reading probably comes from memory buffers rather than from the disk.
Like your program, this reads the dataset twice. but unlike your program it doesn't read the entire dataset once, and then restarts at the beginning to re-read the entire dataset. Much less efficient use of disk channel resources.
Edited improvement. You can replace
do _n3=_n2 to _n while (_dat{_n3}<=date30);
if _dat{_n3}>date30 then leave;
else sin30=sin30 + _sin{_n3};
end;
with:
do _n3=_n2 to _n while (_dat{_n3}<=date30);
sin30=sin30 + _sin{_n3};
end;
The "if test" was needed in an earlier version, but no longer.
