BookmarkSubscribeRSS Feed
🔒 This topic is solved and locked. Need further help from the community? Please sign in and ask a new question.
art297
Opal | Level 21

Ran into an interesting problem last night when using the cntlin option with proc format. The following code produces an error:

data for_format;
  input sym_root $;
  cards;
AAA
BBB
LOW
ZZZ
;
run;

data for_format;
  set for_format (rename=(sym_root=start));
  retain fmtname "$labelfmt" type "C";
  label=_n_;
run;

proc format cntlin = for_format;
run ;

Anyone know how one can include the value 'LOW' in such a case? My work around was to recode 'LOW' to be 'LOWW', but I'd rather no have to change the variable's value.

 

Art, CEO, AnalystFinder.com

 

1 ACCEPTED SOLUTION

Accepted Solutions
Tom
Super User Tom
Super User

You need to add the HLO variable to your control dataset to prevent SAS from trying to detect the LOW HIGH keywords from the text of the START/END values.

data for_format;
  set have (rename=(sym_root=start));
  retain fmtname "$labelfmt" type "C" hlo '   ';
  label=_n_;
run;
proc format cntlin = for_format;
run ;

One way to test is to make the format using code and output the control dataset.

Then try keeping different subsets of the variables in that control dataset to pass back into PROC FORMAT to figure out the minimum set of variables that are needed.

proc format cntlout=want;
  value $labelfmt
  'AAA'='1'
  'BBB'='2'
  'LOW'='3'
  'ZZZ'='4'
  ;
run;

proc format cntlin=want(keep=fmtname type start label hlo); 
run;

View solution in original post

2 REPLIES 2
Tom
Super User Tom
Super User

You need to add the HLO variable to your control dataset to prevent SAS from trying to detect the LOW HIGH keywords from the text of the START/END values.

data for_format;
  set have (rename=(sym_root=start));
  retain fmtname "$labelfmt" type "C" hlo '   ';
  label=_n_;
run;
proc format cntlin = for_format;
run ;

One way to test is to make the format using code and output the control dataset.

Then try keeping different subsets of the variables in that control dataset to pass back into PROC FORMAT to figure out the minimum set of variables that are needed.

proc format cntlout=want;
  value $labelfmt
  'AAA'='1'
  'BBB'='2'
  'LOW'='3'
  'ZZZ'='4'
  ;
run;

proc format cntlin=want(keep=fmtname type start label hlo); 
run;
art297
Opal | Level 21

@Tom: Worked like a charm!

 

Thanks,

Art

 

hackathon24-white-horiz.png

2025 SAS Hackathon: There is still time!

Good news: We've extended SAS Hackathon registration until Sept. 12, so you still have time to be part of our biggest event yet – our five-year anniversary!

Register Now

How to Concatenate Values

Learn how use the CAT functions in SAS to join values from multiple variables into a single value.

Find more tutorials on the SAS Users YouTube channel.

SAS Training: Just a Click Away

 Ready to level-up your skills? Choose your own adventure.

Browse our catalog!

Discussion stats
  • 2 replies
  • 1587 views
  • 3 likes
  • 2 in conversation