@pmorel3 wrote:
Thank you so much ballardw. It works !!!
For each linear regression, I would like to compute automatically, by using my regression coeffcients, this variable: alphaM1 = rp - rm*(reg coef of rm)
without writing by hand my coefficients, what should I do ?
Obviously, I will have 5 series of ''alphaM1''
Where does RP come from? Are the values in a data set?
Are you worried abou tthe intercept coefficient in what you are doing here?
And why 5 series of AlphaM1? You mentioned thousands of Y variables but nothing about 5 series of anything. Or are you just paralleling my example with 5 Y variables?
You can evaluate all of the values rp, what ever that comes from and x if they are in a data set. To extend our previous example:
First create a data set with the X values to evaluate the equation at. If RP needs to be set this you can add it to this data set.
data work.score_x;
input x;
datalines;
.75
1.2
2.4
2.8
3.3
;
Combine with the model parameter estimates. Since you appear to need to apply the same values to ALL of the models then Proc SQL is going to be the tool to combine the sets and do the calculation:
proc sql;
create table work.scored as
select a.label,a.x as xparm,b.x,
(3 - a.x*b.x) as Alpha
from work.est as a, work.score_x as b
order by a.label, b.x
;
quit;
This maintains the Label variable so you know which model was used and adds the the parameter for X from the model estimate results, has the X value used for evaluation and the calculation result.
If RP was the model estimate you would use a.intercept in the place of the 3 above. If it is another variable in the work.score_x data set then use B.RP instead of the 3.
The order by clause means the output will be sorted by the label and the values of x.
The "work.est as a" establishes an alias so you can reference which data set a specific variable comes from. See the A.X and B.X, same variable name on input.
You will get a message in the Log:
NOTE: The execution of this query involves performing one or more Cartesian product joins that
can not be optimized.
because what you are doing is combining every row in each set with every row in the other. This is often referred to as a Cartesian Product.
Now if the purpose of your equation is to get the predicted Y values for X values that you are interested in but do not have Y values directly then you could use the STORE statement to create a special format set that can be used by another procedure to do that evaluation:
proc reg data=work.model
outest=work.est
;
by label;
model value=x;
store out=work.store;
run;
quit;
data work.score_x;
input x;
datalines;
.75
1.2
2.4
2.8
3.3
;
proc plm restore=work.store ;
score data=work.score_x out=work.scoreresults;
run;
Since the work.score_x does not have any specific value of by variables then it evaluates all of the models.
If you were interested just some of the "label" values for specific X values then you would add the appropriate value with the same name as it appeared in Proc Reg. If your by variable is character, then make sure the case is the same, Y1 wouldn't match y1 in the model.
Example:
data work.score_x;
input x label $;
datalines;
.75 y1
1.2 y3
2.4 y1
2.8 y2
3.3 y1
;
This ability to create a stored model parameter this way is extremely powerful. Create the Store set in a permanent library and then any time you want to reuse the model for scoring other data as questions arise.
