The boxplot statement

[aminkarimid]

Hello everybody,

I use codes which is shown below:

proc template;
define statgraph sgdesign;
dynamic _Price _Price2;
begingraph;
   entrytitle halign=center 'Type in your title...';
   entryfootnote halign=left 'Type in your footnote...';
   layout lattice / rowdatarange=data columndatarange=union rows=2 rowgutter=10 columngutter=10 rowweights=(0.8 0.2);
      layout overlay;
         histogram _Price / name='histogram' binaxis=false;
         densityplot _Price / name='Normal' normal();
         densityplot _Price / name='Kernel' kernel() lineattrs=GraphData2(thickness=2 );
         discretelegend 'Normal' 'Kernel' / opaque=false border=true halign=right valign=top displayclipped=true across=1 order=rowmajor location=inside;
      endlayout;
      layout overlay;
         boxplot y=_Price2 / name='box(h)' orient=horizontal;
      endlayout;
      columnaxes;
         columnaxis;
      endcolumnaxes;
   endlayout;
endgraph;
end;
run;

proc sgrender data=work.sampledata02 template=sgdesign;
dynamic _Price="Price" _Price="Price";
run;

The log file is:

WARNING: The boxplot statement named 'box(h)' will not be drawn because one or more of the required
         arguments were not supplied.

What is the Problem?

How can I fix that?

Thanks in advance.

[ballardw · Accepted solution]

IN

proc sgrender data=work.sampledata02 template=sgdesign;
dynamic _Price="Price" _Price="Price";
run;

you did not indicate a value for the dynamic _Price2 used as the Y value for boxplot.