Strip portion of variable

[Q1983]

data test(keep=Disaster);

set test1;

run;

Sample Output

Disaster

Hurricane Harvey
Hurricane Beula
Hurricane Agnes 
Wildfires

If the variable begins with Hurricane  I want to delete it and just show the word after the blank space.  I looked at compress, trim, strip functions however no examples.  How can I accomplish this ??     

[novinosrin]

data have;
input disaster $20.;
datalines;
Hurricane Harvey
Hurricane Beula
Hurricane Agnes
Wildfires
;

data want;
set have;
if scan(disaster,1)='Hurricane' then _disaster=scan(disaster,2);
else _disaster=disaster;
run;

or with IFC function:

data want;
set have;
/*if scan(disaster,1)='Hurricane' then _disaster=scan(disaster,2);*/
/*else _disaster=disaster;*/
_disaster=ifc(scan(disaster,1)='Hurricane' , scan(disaster,2), disaster);
run;

[Astounding]

I guess hurricanes usually receive one-word names.  Just in case there is more than one word following "Hurricane" this might be a little safer:

data want;
set have;
if upcase(scan(disaster,1))='HURRICANE' then _disaster=substr(disaster,11);
else _disaster=disaster;
run;

[ChrisNZ]

or

data WANT;
  set HAVE;
  if upcase(DISASTER) =: 'HURRICANE ' then DISASTER = substr(DISASTER,11);
run;