Hi @mar00390
You nede to create a list of stop words. There might be something to download as a starting point, but otherwise it's just hard work. Given the list and a SAS data set with your strings, an easy solution is to use a format to pick the stop words in the string. The following working code shows the principles.
You need to set proper lengths etc. to make it work with your data. Given your word classes it is probably unnecessary to handle uppercase/lowercase words, but it can be done with a lowcase function on teststr. And be aware that words in the output string are always separated by one blank even if there are more in the input string.
* Test data;
data stopwords;
input stopword $20.;
cards;
abc
xyz
;
run;
data have;
infile cards truncover;
input string $char200.;
cards;
aaa abc bbbbbbbbbb c 123 dddd ffff xyz
123 zzzzzzzzzz xyz hhhhhh
;
run;
* Create format;
data stopfmt; set stopwords end=end;
retain type 'C' fmtname 'stopfmt';
start = stopword;
label = stopword;
output;
if end then do;
hlo = 'O';
start = '';
label = '';
output;
end;
run;
proc format cntlin=stopfmt;
run;
* Remove all words defined as stop words from string;
data want (drop=i teststr); set have;
length newstr $200 teststr $50;
do i = 1 to countw(string,' ');
teststr = scan(string,i,' ');
if put(teststr,$stopfmt.) = '' then newstr = catx(' ',newstr,teststr);
end;
run;
