Select a specific interval in string

[Sk1_SAS]

Hi Team,

I would like to know, if is possible to select the word in a specific interval string.

Ex: Variable name: Comments
I need select the words between PROCESS ORIGIN  and FACTS.

PROCESS ORIGIN sas communities FACTS

PROCESS ORIGIN Google Inc FACTS

PROCESS ORIGIN Google FACTS

Thx !!!

[Jagadishkatam]

Please try

data want;
input string&$100.;
want=prxchange('s/(.*origin)(.*)(FACTS\s)/$2/i',-1,string);
cards;
PROCESS ORIGIN sas communities FACTS
PROCESS ORIGIN Google Inc FACTS
PROCESS ORIGIN Google FACTS
;

[Patrick · Accepted solution]

data want(drop=_:);
  input string&$100.;
  length want $80;
  retain _re;

  if _n_=1 then
    _re=prxparse('/\bprocess origin\b(.*)\bfacts\b/oi');

  if prxmatch(_re, trim(string)) then
    do;
      want=prxposn(_re, 1, string);
    end;

  cards;
PROCESS ORIGIN sas communities FACTS
PROCESS ORIGIN Google Inc FACTS
PROCESS ORIGIN Google FACTS
Process Original Mix by Wehbba facts
blah PROCESS ORIGIN Google Inc FACTS
blah PROCESS ORIGIN Google Inc xxFACTS
blah PROCESS ORIGIN Google Inc FACTSxx
;

[Sk1_SAS]

Thank you!