Perhaps I misunderstood what you are trying to do?
The optional second argument on the FWRITE() function is basically what we used to call Fortran Carriage Control characters.
In that world the first character on the line controlled how the carriage on the typewriter would move.
A space meant normal single spacing.
A 0 meant double spacing.
A 1 meant issue a Form Feed (do load a new piece of paper)
And the + that your code is using meant to overstrike the previous line.
To implement those in a normal text file it mean that for when you write a line of text you do not write the end-of-line characters (which is Windows is Carriage Return and then Line Feed). Instead when your first character is a space you write the endo of line and then write the new line. And when your first character is + you just write the Carriage Return (so the typewriter does not move to a new line) so that when the next line prints the new characters over the others. Doing that to a terminal does not really have the same result (unless you are using an ancient cathode ray tube for a monitor and it has very long retention)
So let's try making those same FWRITE() calls in a data step and look at the contents of the file we get.
filename myfile temp ;
data _null_;
fileref='myfile';
fid=fopen(fileref,'O',0,'P');
rc=fput(fid,'The Three Stooges');
rc=fwrite(fid);
rc=fput(fid,'Shemp Larry and Moe');
rc=fwrite(fid);
rc=fput(fid,'Curly');
rc=fwrite(fid,'+');
rc=fput(fid,'Shemp');
rc=fwrite(fid,'+');
rc=fclose(fid);
run;
data _null_;
infile myfile recfm=f lrecl=80;
input;
list;
run;
Result
RULE: ----+----1----+----2----+----3----+----4----+----5----+----6
1 CHAR The Three Stooges..Shemp Larry and Moe.Curly.Shemp.. 52
ZONE 5662567662576666700566672467772666246604776705666700
NUMR 485048255034FF753DA385D00C122901E40DF5D352C9D385D0DA
NOTE: 1 record was read from the infile MYFILE.
So you see before the second line it wrote the CR and LF. But before the next two it only wrote the CR. And apparently closing the file added the last CR and LF.
You could more easily generate the same thing using PUT statement. If you use RECFM=N then you can decide when to write end of line characters. This step makes the exact same file.
filename myfile temp ;
data _null_;
file myfile recfm=n;
put 'The Three Stooges';
put '0D0A'x 'Shemp Larry and Moe';
put '0D'x 'Curly';
put '0D'x 'Shemp';
put '0D0A'x;
run;
I am still interested in know what you are actually trying to do here. Do you just want to append text to a file? Do you really want to make a file that tries to overstrike ink onto paper?
