Same prefix with 100 varibles need to apply condition statement with single variable?

[rajeshalwayswel]

data have;
input a a1 a2 a3;
cards;
1 2 3 4
1 2 3 1
1 1 2 1
1 2 3 1
run;


data want;
set have ;
if a=1 or a1=1 or a2 =1 or a3=1 then a4=1;
run;


I have variables with same prefix  "a" 100 variables so i'm writing code like above one but i don't need to write 100 variables names i'm using a:=1 but it not working any suggestions

[PeterClemmensen]

Do something like this

data have;
input a a1 a2 a3;
cards;
1 2 3 4
1 2 3 1
1 1 2 1
1 2 3 1
run;

data want;
   set have;
   array MyArray{*} a:;
   if whichn(1, of MyArray[*]) ne 0 then a4=1;
run;

[rajeshalwayswel]

If suppose if mentioned variables are characters(I mean character variable) in place of whichn function which we can use ?

[RW9 · Accepted solution]

First, its not a great idea to have lots of variables, normalise them into rows and you will find programming a lot easier.

As for character, concatenate, then find:

if index(catx(',',of a:),"1") then a4=1;

[PeterClemmensen]

You can use the WHICHC function instead like this

data have;
input a $ a1 $ a2 $ a3 $;
cards;
1 2 3 4
1 2 3 1
1 1 2 1
1 2 3 1
2 2 2 2
run;

data want;
   set have;
   if whichc("1", of a:) ne 0 then a4="1";
run;