Macro variables just hold text. You need to understand what the text means and how to use that text to generate other code to run. First let's just run your %LET statements and see what text is being assigned to the macro variables.
Note the newish feature of the %PUT statement where when you type &=macrovar instead of ¯ovar it displays the name and the value.
156 %LET RUNYEAR=%SYSFUNC(YEAR(%EVAL(%SYSFUNC(TODAY())-10)));
157 %put &=runyear;
RUNYEAR=2021
158
159 %LET NextYEAR=%EVAL(&RUNYEAR.+1);
160 %put &=nextyear;
NEXTYEAR=2022
161
162 %LET PREVYEAR=%EVAL(&RUNYEAR.-1);
163 %put &=prevyear;
PREVYEAR=2020
164
165 %LET PREV2YEAR=%EVAL(&RUNYEAR.-2);
166 %put &=prev2year;
PREV2YEAR=2019
167
168
169 %LET RunYearDT = 2020-01-01 00:00:00;
170 %put &=runyeardt ;
RUNYEARDT=2020-01-01 00:00:00
171
172 %LET RunYearD = 01JAN2020;
173 %put &=runyeard ;
RUNYEARD=01JAN2020
174
175
176 %LET ContributionStartDT = '01/01/2014' and '12/31/2020';
177 %put &=ContributionStartDT ;
CONTRIBUTIONSTARTDT='01/01/2014' and '12/31/2020'
So the first one is the most complex. First let's simplify it a little.
%LET RUNYEAR=%SYSFUNC(YEAR(%SYSFUNC(TODAY())-10));
The %SYSFUNC() macro function let's you call regular SAS functions in macro code (almost all SAS functions can be called this way). In this case YEAR() and TODAY() are the functions being called, notice how each one needs its own %SYSFUNC() wrapper. The YEAR() function returns the year from a SAS date value. The TODAY() function returns the date value from the computers clock. SAS stores dates as number of days so subtracting 10 is moving 10 days into the past. Notice that when calling a SAS function in macro code via %SYSFUNC() you do not need to call %EVAL() for arithmetic you want to do on numeric arguments. The %SYSFUNC() interface to the SAS functions will make sure those expressions are evaluated.
Then you have two %LET statements that using %EVAL() macro function to perform some simple integer arithmetic. So in this one:
%LET NextYEAR=%EVAL(&RUNYEAR.+1);
You are passing into the %EVAL() function the string 2021+1 which it will see as a request to add the two numbers represented by the character strings on either site of the plus sign. The resulting number will be an integer that is then converted into a digit string that represents that number. In this case the string 2022.
Near the end you are making two macro variables with DT and D suffixed to their name. The strings being assigned look like the way that the DATETIME and DATE formats would display datetime and date values. But more importantly those strings are strings that the DATETIME and DATE informats will recognize as dateime and date values. So you could use those strings to create DATETIME or DATE literals by adding quotes and the proper suffix. For example you might use both of those macro variables in SAS code like this to compare some datetime or date variables to those constant values.
where run_datetime > "&RunYearDT"dt or run_date > "&RunYearD"d ;
The last example is stranger as you are assigning a multiple word string to the macro variable. It is probably not very useful for generating SAS code. You might use it to generate a title or a footnote. So code like:
title1 "Report for Contributions between &ContributionStartDT";
Would result in this actual TITLE statement:
title1 "Report for Contributions between '01/01/2014' and '12/31/2020'";
Or it might be useful in some code passed to a remote database where date constants can be expressed in that way. So perhaps something like:
proc sql ;
connect to oracle ..... ;
create table want as select * from connection to oracle
(select * from contributions where datevar between &ContributionStartDT)
;
So that the query sent to the ORACLE database is:
select * from contributions where datevar between '01/01/2014' and '12/31/2020'
But perhaps want you really want to do is use the PREVYEAR and NEXTYEAR macro variables to generate date literals that you could use in SAS code instead? So something like this in your program:
where datevar between "01JAN&prevyear"d and "31DEC&nextyear"d
Would result in this SAS code being run:
where datevar between "01JAN2020"d and "31DEC2022"d
