Resolving a Macro variable in single and double quotes

[SasStatistics]

I have the following code, where I from SAS send an automatic mail. The problem is that the macro variable does not get resolved, and I believe it has to do with the quotes but I can't figure out how to solve it. 

%let country. = USA; 

FILENAME Mailbox 
				EMAIL TO=("MyMail@gmail.com")
				SUBJECT="An Example Mail" 
				 replyto="Mail2@gmail.com"				
				;
		DATA _NULL_;
		FILE 	Mailbox 
		type='text/html';
		PUT "Some Random Text" '<br><br>'
	
		'<a href="MyDirectoryPath\&country.">MyDirectoryPath\&country.</a>' '<br><br>'
		;
		RUN;

So the line of code that is the problem is: 

'<a href="MyDirectoryPath\&country.">MyDirectoryPath\&country.</a>' '<br><br>'

In the mail the following shows up: 

MyDirectoryPath\&country

But it should be: MyDirectoryPath\USA, i.e. the macro variable should resolve. 

Any suggestions? 

[Amir]

Hi @SasStatistics.,

The %let statement has a "." after "country", so I removed it.

The following code:

%let country = USA;

data _null_;
   text = cat("Some Random Text"
             ,'<br><br>'
             ,'<a href='
             ,quote("MyDirectoryPath\&country.")
             ,">MyDirectoryPath\&country.</a>' '<br><br>'"
             );
   put text;
run;

produces:

Some Random Text<br><br><a href="MyDirectoryPath\USA">MyDirectoryPath\USA</a>' '<br><br>'

Is that what you're looking for?

Kind regards,

Amir.

[SasStatistics]

The solution was: "Switching " and ' should solve the problem."

[Kurt_Bremser]

Build the string using single quotes to mask double quotes, and double quotes around macro variables:

%let country = USA;

data _null_;
string =
  'Some Random Text<br><br><a href="' !!
  "MyDirectoryPath\&country." !!
  '">' !!
  "MyDirectoryPath\&country.</a><br><br>"
;
put string;
run;

[andreas_lds · Accepted solution]

Switching " and ' should solve the problem.

[SasStatistics]

Do you know why this is so? Is it some general principle?