Remove all Text before Comma

[KC_16]

Hi,

I have a variable (Comments_Line) where by it's prefixed with text that I don't need and it always follows the same structure. 

I need to remove any text before the first comma and if possible, remove the comma too! 

An example of this would be: 

Kevin, welcome to your new account

Abi, we miss you

ideally what i would like to see on the examples used above would be the following output:

welcome to your new account

we miss you

Any idea is this is possible please and if it is, how I would go about doing this?

[Sathish_jammy · Accepted solution]

data want;
set have;
want=scan(Comment_variable,-1,',');
run;

[KC_16]

Thank you Sathish_jammy

[PeterClemmensen]

data have;
input Comments_Line $ 1-100;
infile datalines truncover;
datalines;
Kevin, welcome to your new account
Abi, we miss you
;

data want;
    set have;
    NewVar=scan(Comments_Line,-1,',');
run;

Result:

Comments_Line                      NewVar
Kevin, welcome to your new account welcome to your new account
Abi, we miss you                   we miss you

[Tom]

There are some boundary conditions your example test data don't cover.  What do you want when there are no commas? Comma is the FIRST character.  There are two or more commas?

Here is your requirment.

I need to remove any text before the first comma and if possible, remove the comma too! 

Here is code to do that for the variable named STRING in the dataset named HAVE.

data want;
  set have;
  string=left(substrn(string,indexc(string,',')+1));
run;

This will handle strings that start with comma, have no comma, and have multiple commas.

The SUBSTRN() will handle the case if the first comma is at the end of the variable so that adding one would be trying to index past the end of STRING.

The LEFT() function will remove space(s) that follow the comma.  Note this means that for strings without any commas it will remove leading spaces.