You are still missing the description of what you are trying to do.
Let's make another guess. You have a really long string of words delimited by semi-colon and you want to break it into smaller strings, but without splitting individual words. So essentially you are doing word wrapping like a word processor would to flow a paragraph onto a page.
So if the original string has a maximum length of 1000 and you want the new strings to each have a maximum length of 200 then you will probably need between a maximum of 5 to 10 of them to hold all of the possible words. (What would happen if every word was exactly 100 characters long?)
data want ;
set abc ;
array col [10] $200 ;
target=1;
do source=1 to countw(old,';');
if col[target]=' ' then col[target]=scan(old,source,';');
else if 200 < length(catx(';',col[target],scan(old,source,';'))) then do;
target=target+1;
col[target]=scan(old,source,';');
end;
else col[target]=catx(';',col[target],scan(old,source,';'));
end;
run;
Or more simply generate the TALL structure instead. You can always add in a PROC TRANSPOSE step to convert it back into one observation with multiple columns.
data tall ;
row+1;
set abc ;
length col 8 new $200;
col=1;
do source=1 to countw(old,';');
if source>1 and vlength(new) < length(catx(';',new,scan(old,source,';'))) then do;
output;
col=col+1;
new=' ';
end;
new=catx(';',new,scan(old,source,';'));
end;
if col=1 or new ne ' ' then output;
drop source old;
run;
proc transpose data=tall out=want(drop=_name_) prefix=col;
by row;
id col;
var new;
run;
Click image to register for webinar
