Read Money as numeric

[Miah]

I am trying to change the format of column Gross, which contains values like $50,319,942. I wish to make my program treat this variable as numeric. 

This is my code but it is not displaying the values of this column. 

DATA movies;
INFILE "/folders/myfolders/GrossDays.txt" DLM='09'x MISSOVER FIRSTOBS=2 DSD;
INPUT Title :$100. Date :ANYDTDTE20. Gross Theaters Distributor $;
RUN;

PROC PRINT DATA=movies;
FORMAT Date DATE9.;
RUN;

PROC PRINT DATA = music;
	FORMAT Date DATE. ;
	FORMAT Gross 10. ;
RUN;

DATA movies;
   SET movies;
   TheaterAvg = (Gross/Theaters);
RUN; 

PROC PRINT DATA = movies;
RUN;

[art297]

You just need to add an informat when inputting gross. e.g.:

DATA movies;
  INFILE "/folders/myfolders/GrossDays.txt" DLM='09'x MISSOVER FIRSTOBS=2 DSD;
  INPUT Title :$100. Date :ANYDTDTE20. Gross dollar12. Theaters Distributor $;
RUN;

Art, CEO, AnalystFinder.com

[Tom]

Make sure to include the : prefix so that it uses list mode input since the source file is delimited and not fixed columns.

  INPUT Title :$100. Date :ANYDTDTE. Gross :dollar. Theaters Distributor :$20.;

You don't need widths on your INFORMATs when using list mode, SAS will ignore them.

But you do want to include the width in the $xx. informats since that way SAS can use the width the make a better guess at what length you want the character variables to use.

[art297]

@Tom: It works, in this case, with or without the : for gross as long as one includes the dollar. informat

@Miah: One additional problem with your code:

PROC PRINT DATA = music;
	FORMAT Date DATE. ;
	FORMAT Gross 10. ;
RUN;

Shouldn't that have been data = movies ?

Art, CEO, AnalystFinder.com