READ only first and last obs

[Ronein]

Hello

I want to select first and last row of a data set.

I saw this code that say that in the case that data set is very big then we can tell SAS to read only first and last rows.

May anyone explian this code?

I know NOBS option in SET.

But I dont understand how this code work and how SAS knows to read only first and last observations.

What is the meaning of "STOP" in this code?

What is the meaning of "OUTPUT" in this code?

Why using 2 SET statements?

What is POINT var?

Thank you

data first_last_rows;
set SASHELP.cars nobs=_nobs_;
output;
set SASHELP.cars  point=_nobs_;
output;
stop;
run;

[Patrick]

The first SET statement reads the first observation from the source table as you're used to it. The OUTPUT statement then writes this row to the target table.

In the first statement there is also keyword nobs=_nobs_ 
This stores the total number of observations in variable _nobs_;

The second SET statement then uses direct access via keyword point=_nobs_ 

This reads the observation number stored in _nobs_ from the source table - and with _nobs_ containing the total number of observations this is going to be the very last observation.

And the last statement STOP then instructs SAS to not further iterate through the data.

[mkeintz]

You could even eliminate the STOP statement by using the (obs=1) dataset name parameter, as in:

data first_last_rows;
  set SASHELP.cars (obs=1) ;
  output;
  set SASHELP.cars  point=_nobs_ nobs=_nobs_;
  output;
run;

[Tom]

If the input dataset has only one observation it will be output twice.  Do you want that?