/* The input data set and key variable(s) to include in all data sets */
%let data=sashelp.heart;
%let keys=ageatstart;
/* A list of variable names withOUT the KEYS*/
proc contents noprint out=sansid(keep=name varnum) data=&data(drop=&keys);
run;
/* put them in varnum order */
proc sort data=sansid;
by varnum;
run;
/* create 3 approximately equal groups */
proc rank out=sansid groups=3;
var varnum;
ranks group;
run;
/* Generate data set name with keep= data set option with a */
/* name range variable list from the first and last name in each GROUP*/
/* write the generated code to a file*/
filename codegen temp;
data _null_;
file codegen;
set sansid;
by group;
if first.group then put +3 'vgroup' group '(keep=' "&keys" +1 name '--' @@;
if last.group then put +1 name ')';
run;
/* create the new data sets*/
data
%inc codegen / source2;
;
/*This merge is important to unsure the keys are on the left and not in the name ranges*/
merge &data(keep=&keys) &data(drop=&keys);
run;
Message was edited by: data _null_
