Proc Transpose character numeric issue

[Satish_Parida]

data have;
input byvar a b c;
cards;
1 100 200 300
2 400 500 600
;
run;

proc sort data=have;
by byvar;
run; 
                                                                                   
proc transpose data=have 
				out=want(keep=byvar _name_ Value1 rename=(_name_=var_name Value1=Value))
				prefix=Value;
  by byvar;                                                                          
  var a b c;                                                      
run;

Can we have the datatype of column "Value" in "want" table set to character datatype during transpose?

If we have a mixed datatype in the input "have" table it is working fine.

[PeterClemmensen · Accepted solution]

I don't think so. Perhaps simply do it in a data step?

data have;
input byvar a b c;
cards;
1 100 200 300
2 400 500 600
;
run;

data want(keep=byvar name Value);
   set have;
   array _{3} a b c;
   do i=1 to dim(_);
      name=vname(_[i]);
      Value=put(_[i], 8. -l);
      output;
   end;
run;

[PeterClemmensen]

@Satish_Parida did you try my code and did it work for you? 🙂