Percentile using mean

[Sathish_jammy]

Hi,

I have values (1 to 300) in a column i want to find the mean and std of 33.33rd percentile for that values.

How do i solve that. please help me!...

[RW9]

Result 1 on google search seems to have the answer:

https://blogs.sas.com/content/iml/2013/10/23/percentiles-in-a-tabular-format.html

For non-standard percentiles use stdzise.

[FreelanceReinh · Accepted solution]

Hi @Sathish_jammy,

Now you've started a second thread for essentially the same question -- not ideal.

I would probably let PROC RANK identify the percentiles (i.e. tertiles) and then use PROC SUMMARY to calculate the descriptive statistics for each of the three groups. Using your data from the other thread as dataset HAVE:

proc rank data=have out=want groups=3;
var weight;
ranks tertile;
run;

proc summary data=want nway;
class tertile;
var weight follw1_weight;
output out=stats mean= std= / autoname;
run;

[Sathish_jammy]

Thank u so much! it works well...

But how do i get the mean difference & STD difference  ,as well p-value for each 3 tertiles.

Could u please help me again.

[FreelanceReinh]

Well, a p-value is always associated with a statistical hypothesis test. So, you'd have to specify this test. As a start, let's assume that you want what is probably the most common choice in the situation you described in the other thread: the two-sided t-test for paired samples. But you should double-check your requirements.

The corresponding SAS procedure, PROC TTEST (with the PAIRED statement), does not only compute "the" p-values, but also the requested summary statistics. Continuing with dataset WANT from my first reply in this thread:

proc sort data=want;
by tertile;
run;

ods select none;
ods output ttests=ttest
           statistics=tstats;
proc ttest data=want;
by tertile;
paired weight*follw1_weight;
run;
ods select all;

data want2;
merge tstats(keep=tertile mean stddev)
      ttest(keep=tertile probt rename=(probt=p_value));
by tertile;
run;

[Sathish_jammy]

You are really awesome!... @FreelanceReinh

Thank you so much...