PROC SQL - formatting using SUBSTR

[CamRutherford]

Hello,

Looking for some assistance...

I have a dataset with a column containing various member_id's (see below example). I would like the first character, everything left of the dash, to be moved to the end of the string prefixed with two 0's and the dash removed. For example, using the below example, looking at the first member id, I'd like 5-12344 to become 12344005.

COLUMN A

5-12344

5-1234

5-123456

7-345

2-3456

Thanks

[Reeza]

Use the SCAN() function to separate the components. 

[ballardw]

cats(scan(a,2,'-'),'00',scan(a,1,'-'))

[PGStats]

Another option - regular expression substitution :

data have;
input id :$12.;
datalines;
5-12344
5-1234
5-123456
7-345
2-3456
;

proc sql;
select id, prxchange("s/(\d+)\-(\d+)/\200\1/o", 1, id) as newId length=15
from have;
quit;

[CamRutherford]

Thanks @PGStats and @ballardw.

Both work great! However I now want to increase the length of the string to be length 10 and prefixed with 0's if it is less than this until it reaches the correct length. Any ideas?

[Ksharp]

data have;
input id :$12.;
datalines;
5-12344
5-1234
5-123456
7-345
2-3456
;
run;
data want;
 set have;
 want=repeat('0',9);
 x=scan(id,1,'-');
 y=scan(id,-1,'-');
 substr(want,1,length(y))=y;
 substr(want,10-length(x)+1)=x;
run;

[PGStats]

Since I was already using heavy artillery, here is some more:

data have;
input id :$12.;
datalines;
5-12344
5-1234
5-123456
7-345
2-3456
;

proc sql;
select id, 
    put(input(prxchange("s/(\d+)\-(\d+)/\200\1/o", 1, id),10.),z10.0) as newId
from have;
quit;