Someone else with have to explain how to use PROC JSON. I find it too confusing. It is much easier to just use a data step to write JSON text.
First let's make some actual sample SAS data.
data have;
infile cards dsd dlm='|' truncover ;
input (TIN plan_type provider_type provider_group_affiliation languages_spoken ) (:$100.) ;
cards;
123456789|Medical|Facility|Group ABC|English
123456790|Medical|Facility|Group ABC|English,Spanish
123456791|Medical|Facility|Group ABC|
;
Notice how the LANGUAGE_SPOKEN data is using comma as delimiter between the individual values.
Now let's make a data step to write the JSON.
I will put in a branch to handle some variables like LAGUAGES_SPOKEN differently.
filename json temp;
data _null_;
length name $32 value item $200;
set have end=eof;
file json;
if _n_=1 then put '[' @;
else put ',' @;
sep='{' ;
do name='TIN','plan_type','provider_type','provider_group_affiliation','languages_spoken';
value=vvaluex(name);
put @2 sep $1. name :$quote. ':'@;
sep = ',';
if name not in ('languages_spoken') then put value :$quote. @;
else do;
item = scan(value,1,',');
put '[' item :$quote. @;
do index=2 to countw(value);
item=scan(value,index,',');
put ',' item :$quote. @;
end;
put ']' @ ;
end;
put;
end;
put ' }' ;
if eof then put ']';
run;
Results:
[{"TIN" :"123456789"
,"plan_type" :"Medical"
,"provider_type" :"Facility"
,"provider_group_affiliation" :"Group ABC"
,"languages_spoken" :["English" ]
}
,{"TIN" :"123456790"
,"plan_type" :"Medical"
,"provider_type" :"Facility"
,"provider_group_affiliation" :"Group ABC"
,"languages_spoken" :["English" ,"Spanish" ]
}
,{"TIN" :"123456791"
,"plan_type" :"Medical"
,"provider_type" :"Facility"
,"provider_group_affiliation" :"Group ABC"
,"languages_spoken" :["" ]
}
]
