ODS LAYOUT borders

[A_Kh]

Dear Community, 

I'm trying to define top border line (thick if possible) of ODS LAYOUT to separate the header from tables in my ODS pdf document, but not getting the desired result with Style= {borderstyle=/bottomborderstyle=}  options. Below is the code to produce the page. Does anyone know how to set the specific borders? 

Thank you!

*create style template;
proc template;
	define style textframe;
		parent= styles.pearl;
			class usertext/
				frame=box
					backgroundcolor= _undef_;
				class header/
			borderbottomstyle=solid
		backgroundcolor= _undef_;
	end;
run; 

ods _all_ close; 
options nodate nonumber topmargin=0.3in bottommargin=0.2in leftmargin=0.2in rightmargin=0.2in;
ods escapechar='~';

ods pdf file= "&dir\test_doc.pdf" startpage=no style=textframe;
	footnote j=l "~S={font_face='Arial' font_weight=medium font_size=9pt URL='https://communities.sas.com'} ~S={font_face='Arial' font_weight=medium font_size=9pt FOREGROUND=blue} communities.sas.com"
			 j=c "~S={font_face='Arial' font_weight=medium font_size=9pt} CONFIDENTIAL"
			 j=r "~S={font_face='Arial' font_weight=medium font_size=9pt} Page ~{thispage}";
	title j=l "~S={font_face='Arial' font_weight=bold font_size=11pt} Assessment Name" 	
		  j=r "~S={font_face='Arial' font_weight=bold font_size=11pt bottomborderstyle=solid} Assessment Method";

		ods layout absolute width=19cm height=23cm; 

			ods region x=0.2in y=0.6in width=3.19in height=0.7in style={borderstyle=solid borderwidth=1};
				ods text="~{newline} ~S= {fontfamily='Arial' font_size=9pt font_weight=bold}	Qualitative Summary";
				
			ods region x=0.2in y=1.6in width=3.19in height=1.3in style={borderstyle=solid borderwidth=1};
				ods text="~{newline} ~S= {fontfamily='Arial' font_size=9pt font_weight=bold}	Summed Score Model" ;
				
			ods region x=4.2in y=0.6in width=3.19in height=0.7in style={borderstyle=solid borderwidth=1};
				ods text="~{newline} ~S= {fontfamily='Arial' font_size=9pt font_weight=bold}	Nested Model Comparison";
				
			ods region x=4.2in y=1.6in width=3.19in height=1.3in style={borderstyle=solid borderwidth=1};
				ods text="~{newline} ~S={fontfamily='Arial' font_size=9pt font_weight=bold}		XYT Graded Model";  
				         
			ods region x=0.4in y=3.3in width=7.0in height=5.5in style={backgroundimage="&dir\example-figure.png" };
				ods text='~S={fontfamily="Arial" textalign=center just=c font_size=10pt font_weight=bold} 	Item Results Map with reliability curve';

		ods layout end;

	title;footnote;
ods pdf close; 

[Kathryn_SAS · Accepted solution]

The style attribute name is BORDERBOTTOMSTYLE. I would suggest the following:

	title j=l "~S={font_face='Arial' font_weight=bold font_size=11pt
borderbottomwidth=2pt
 borderbottomcolor=black } Assessment Name" 	
		  j=r "~S={font_face='Arial' font_weight=bold font_size=11pt borderbottomwidth=2pt
 borderbottomcolor=black} Assessment Method";

[A_Kh]

@Kathryn_SAS , 

Awesome! 

This solved my problem, thank you so much!