First thing: when discussing rules for coding refer to VARIABLES in your data set. "Encounter" is not a variable and you do not define what an encounter actually is in terms of the data shown.
Second: Show the data you have first, then show a desired result.
Third: Show the data you have in the form of data step code. This becomes somewhat critical when dealing with certain types of data, such as dates, times or datetime values. We see a "date" and will assume that it is a SAS date value when you my not actually have such. This is especially important if you provide example dates that look like 01/02/03. That value without a description could be 2Jan2003, 1Feb2003, 3Feb2001 (or possibly years 1903 and 1901).
For instance, ID variables such as your Patient_mrn quite often are not numeric but character. When sort order may be important, as in this problem, incorrect guess on our part my mean that our code doesn't work as expected.
I have built a partial data set and have some suggested code:
data have;
input PATIENT_MRN ADM_DATE : mmddyy10. Tested ;
format adm_date mmddyy10.;
datalines;
10521 7/21/2016 0 0 0
10764 7/5/2013 0 0 0
10764 5/1/2015 1 0 1
10764 1/21/2016 0 1 1
100002 12/27/2012 1 0 1
100088 1/2/2014 1 0 1
100293 10/16/2013 1 0 1
100293 5/15/2015 0 0 0
100293 5/18/2015 1 1 1
100293 7/31/2015 0 1 1
100369 3/25/2017 0 0 0
109825 8/28/2016 0 0 0
600563 8/10/2012 1 0 1
1000063 10/23/2018 1 0 1
1000083 5/20/2015 1 0 1
1000262 10/30/2017 0 0 0
1000270 1/5/2012 0 0 0
;
/*may need to include this step with your data*/
/*proc sort data=have;*/
/* by PATIENT_MRN ADM_DATE;*/
/*run;*/
data want;
set have;
retain testdate;
lastdate = lag(adm_date);
by patient_mrn ;
if first.patient_mrn then call missing(lastdate,testdate);
if lastdate then visit12mo = (intck('month',lastdate,adm_date,'C') le 12);
else visit12mo=0;
if tested then testdate=adm_date;
if testdate then tested_12= (intck('month',testdate,adm_date,'C') le 12);
else tested_12=0;
drop lastdate testdate;
run;
The Sort order is important to use BY processing which is critical to doing things correctly for the first record of each patient.
By group processing creates automatic variables in a data step that indicate whether the current record is the first or last of the group that are 1/0 coded values which SAS will use a true/false in comparisons.
The Retain function keeps the value of a variable across data step boundaries. So we can keep the last date that a test was performed (assuming 1 in tested means that, you did not state such). The Lag function returns the value of a variable from the previous time the condition executes (use of Lag in conditional statements like IF gets tricky) as used here it will have the value of the previous record's Adm_date which is what I have to assume is an encounter.
The INTCK function is used to return the number of intervals between two date, time or datetime values and is the basic tool for testing duration. Your definition of "12 months" is a bit incomplete as you do not clearly state whether the interval from 31Jan2016 to 1Feb2016 would one month or not, i.e. counting month boundaries. I have guessed that you mean more of the duration and used the 'C' switch, for continuous, so that dates within the month are considered.
If you have a different interpretation of "month" you may want a different switch or option. Note that Intck will do 'Year' as well. In which case you might want to use that and compare to 1 instead of 12.
https://communities.sas.com/t5/SAS-Communities-Library/Working-with-Dates-and-Times-in-SAS-Tutorial/... has a PDF with much information about dates.
