NOTE: c1 is not estimable. NOTE: CONTRAST c1 is not estimable.

[abudyak]

Can anyone explain why I keep getting this note: 

NOTE: c1 is not estimable.

NOTE: CONTRAST c1 is not estimable.

It will not print out the contrast because of this. I tried other contrasts and I get the same result even though it worked before.

data car;
infile cards expandtabs;
input mm year mpg @@;
cards;
1	2005	26.5
2	2005	24.5
3	2005	27.5
4	2005	30.5
5	2005	20.5
6	2005	26.5
7	2005	29
8	2005	26.5
1	2010	23.5
2	2010	22.5
3	2010	27.5
4	2010	28.5
5	2010	21.5
6	2010	23.5
7	2010	27.5
8	2010	27
1	2015	26.5
2	2015	26
3	2015	32.5
4	2015	30
5	2015	25
6	2015	26
7	2015	30
8	2015	28.5
1	2020	23.5
2	2020	25
3	2020	33.5
4	2020	28.5
5	2020	25
6	2020	27
7	2020	35
8	2020	32
;

proc glm data=car;
	class mm year;
	model mpg= mm year;
	output out=car1 predicted=ypred residual=res;
	means mm year;
run;

proc univariate data=car1 plot normal;
	var res;
run;

proc glm data=car1;
	class mm year;
	model mpg= mm year;
	estimate 'c1' mm 0 0 1 -1 0 0 -1 0;
	contrast 'c1' mm 0 0 1 -1 0 0 -1 0;
run;

[PGStats]

The values of the linear hypothesis vector should sum up to zero, for example:

proc glm data=car1;
	class mm year;
	model mpg= mm year;
	estimate 'c1' mm 0 0 2 -1 0 0 -1 0;
	contrast 'c1' mm 0 0 2 -1 0 0 -1 0;
run;