Minimum of prior values

[Doug____]

If I have a set of values ordered by ID and date, how do I determine the minimum value for each record at from all prior dates? I've tried using RETAIN but don't seem to be obtaining the correct results.

[Astounding · Accepted solution]

Here's an approach that assumes you do NOT want the current value considered when computing the PRIOR minimum:

proc sort data=have;

by id date;

run;

data want;

set have;

by id date;

if first.id then min_val = .;

retain min_val;

output;

min_val = min(min_val, varname);

run;

[Doug____]

This method works well for what I'm doing. Any variations for when missing values appear in the series?

[Astounding]

The MIN function ignores missing values.  So I'm assuming you would like to add the possibility that the calculated minimum value comes out missing if one of the incoming values is missing.  That's slightly harder but not a great deal different.  After sorting:

data want;

set have;

by id date;

retain min_val;

if first.id then do;

   min_val = .;

   output;

   min_val = 1e17;

end;

else output;

if varname < min_val then min_val = varname;

run;