Macro Resolution - Using quotation marks or not

[SasStatistics]

Assume we have the following two alternatives: 
Alternative 1 (Please note the comment with the dot, is this better practice to use?): 

%let country = USA; 

%if "&country" = "USA" %then %do;  * Is it better to write: %if "&country." = "USA" %then %do ?; 
	%put Note: right; 
%end; 
%else %do; 
	%put Note: Wrong; 
%end; 

Alternative 2 (Please note the comment with the dot, is this better practice to use?): 

%let country = USA; 

%if &country = USA %then %do; * Is it better to write: %if &country. = USA %then %do ?;
	%put Note: right; 
%end; 
%else %do; 
	%put Note: Wrong; 
%end; 

Both alternatives work but it seems to me like the first alternative "should be preferred" since it is text (USA) we are dealing with? Any opinions on this? 

Finally, why would the following produce "wrong"? 

%let country = USA; 

%if "&country" = 'USA' %then %do; 
	%put Note: right; 
%end; 
%else %do; 
	%put Note: Wrong; 
%end; 

Regarding the comments, is it better practice to use a dot? 

[Kurt_Bremser · Accepted solution]

It is never wrong to use the dot, so it is recommended, especially for beginners, to use it. It also makes macro references more visible in the Enhanced Editor.

Since the macro processor knows only one "data type" (text), quotes are not necessary; in fact, they become part of the text, and that is why your comparison of single vs. double quotes will always return false.

[SasStatistics]

If I understand it correctly, text is NOT the same as string?

Example 1 (Text): This is some text
Example 2 (String): "This is a string"

[PaigeMiller]

---

@SasStatistics wrote:

If I understand it correctly, text is NOT the same as string?

Example 1 (Text): This is some text
Example 2 (String): "This is a string"

---

That's not it. Macro variables are always text. You do not need to use quotes around the value of macro variables, because they are always text.

When you put macro variables in quotes, then the quotes are part of the macro variable value. In the code below &a1 is a character string that has six characters, a double-quote, then a capital T and then an e and then an x and then a t and then a double quote. In the code below &a2 is a character string of four characters, and none of the four characters is a double quote.

%macro nothing;

%let a1 = "Text";
%let a2 = Text;

%if &a1=Text %then %put TRUE; %else %put FALSE;
%if &a2=Text %then %put TRUE; %else %put FALSE;
%if &a1=&a2 %then %put TRUE; %else %put FALSE;
%mend;

%nothing

As you can see in the results, &a1 does not equal Text because &a1 has quotes.

DO NOT PUT QUOTES around the values of your macro variable. Generally, quotes are simply not need when defining or evaluating macro variables.

[Kurt_Bremser]

For the macro processor, both are just text, with the second one containing quotes.

[Tom]

The reason you might want to include quote characters in the strings you are comparing to protect against values to look like operators to the implied %EVAL() function call you are generating.

For example when testing two letter state abbreviation codes.  Try testing for the code for Oregon.

The reason the last test is false is pretty obvious, the first character of the strings being compared are different.  " does not equal '