Labeling multiple variables

[petlove]

Hi all,

I am trying to label all variables to new label which will have variable name and its label.

e.g. Current label of AETERM is "Reported Term for the Adverse Event". I am trying to re-label it to "AETERM Reported Term for the Adverse Event".

can we do this by call execute?

Thank you.

[PeterClemmensen]

I think you are looking for something like in this example

http://support.sas.com/kb/24/664.html

[Reeza · Accepted solution]

---

@petlove wrote:

Hi all,

I am trying to label all variables to new label which will have variable name and its label.

e.g. Current label of AETERM is "Reported Term for the Adverse Event". I am trying to re-label it to "AETERM Reported Term for the Adverse Event".

can we do this by call execute?

Thank you.

---

Yes you can, use PROC DATASETS and feed the labels in.

*Create label data set;
data label_data_set;
length name label $25.;
name="Sex"; label="Gender"; output;
name="height"; label="Height (in)"; output;
name="weight"; label="Weight (lbs)"; output;
run;
 
 
*Create sample dataset to apply label;
data class;
set sashelp.class;
run;
 
 
*Create macro variable that holds label statement;
proc sql noprint;
select catx("=", name, quote(trim(label)))
  into :label_list separated by " "
from label_data_set;
quit;
 
 
*Display macro variable in log;
%put &label_list.;
 
 
*Apply labels without recreating dataset;
proc datasets library=work;
modify class;
label &label_list.;
run;quit;
 
 
*Print the dataset to display new labels;
proc print data=class label noobs;
run;

[petlove]

Thank you Reeza...