Is there a comparable function in sas like regexp_extract?

[Hoibai]

I have this string: "Cdtr":{"Nm":"DEUTSCHE BANK"}

How can I implement this in SAS like the function

regexp_extract(fulltxinf_intx, '"Cdtr":."Nm":"([^"]+)', 1) as String_Ort

Thanks

[PaigeMiller]

@Hoibai 

Please tell us what this regexp_extract function does.

[Hoibai]

The function returns me the result DEUTSCHE BANK, that the parameters Cdtr":{"Nm": are in front of it.

My string: "Cdtr":{"Nm":"DEUTSCHE BANK"}

regexp_extract(string, '"Cdtr":."Nm":"([^"]+)', 1) as String_Ort

[Quentin]

Can you give a few more examples of strings you would like to parse?  

[ChrisNZ]

Like this?

data T;
  STR1 = '"Cdtr":{"Nm":"DEUTSCHE BANK"}';
  STR2 = prxchange('s/"Cdtr":."Nm":"([^"]+).*/\1/', 1, STR1);
  put STR2=;
run;

STR2=DEUTSCHE BANK

[ChrisNZ]

Not too sure why you have

  STR2 = prxchange('s/"Cdtr":."Nm":"([^"]+).*/\1/', 1, STR1);

I'd replace the . with a {

  STR2 = prxchange('s/"Cdtr":{"Nm":"([^"]+).*/\1/', 1, STR1);

[Hoibai]

The problem is, the first record is with {"Cdtr":{"Nm":"DEUTSCHE BANK"} .

The second record  is with '{"Cdtr":{"Nm":"VERGOELST GMBH"}'

according to the constant variables {"Cdtr":{"Nm":, each record in the file has a different value.

[ChrisNZ]

That's why I use a variable name. Whatever is in STR1 will be read into STR2.
Swap with the names of your variables.

[Hoibai]

my string is 300 - 400 Bytes long.

{"Cdtr":{"Nm":"DEUTSCHE BANK"},"CdtrAcct":{"Id":{"IBAN":"DE0111111111111111111100"}},

[ChrisNZ]

The parsing should still work. Have you tried?

[Hoibai]

my string begins

{"ar:pacs.003.002.04":{"Cdtr":{"Nm":"DEUTSCHE BANK"},"CdtrAcct":{"Id":{"IBAN":"DE0111111111111111111100"}}

that's why I get this result: {"ar:pacs.003.002.04":{DEUTSCHE BANK

[Quentin]

Can you please give a few examples (just 5-10) of the full string you are trying to parse?  It will help people help you.

[ChrisNZ]

that's why I get this result: {"ar:pacs.003.002.04":{DEUTSCHE BANK

data HAVE;
  input STR1 &:$300.;
cards;  
{"ar:pacs.003.002.04":{"Cdtr":{"Nm":"DEUTSCHE BANK"},"CdtrAcct":{"Id":{"IBAN":"DE0111111111111111111100"}}
{"Cdtr":{"Nm":"DEUTSCHE BANKX"},"CdtrAcct":{"Id":{"IBAN":"DE0111111111111111111100"}}
{"ar:pacs.003.002.04":{"Cxxx":{"Nm":"DEUTSCHE BANKY"},"CdtrAcct":{"Id":{"IBAN":"DE0111111111111111111100"}}
run;

proc sql; 
  select ifc( prxchange('s/.*"Cdtr":{"Nm":"([^"]+).*/\1/', 1, STR1) = STR1, ' ', prxchange('s/.*"Cdtr":{"Nm":"([^"]+).*/\1/', 1, STR1) ) as STRING_ORT
  from HAVE;
quit;  

I cater for cases when there is not matching pattern with the ifc() test.

STRING_ORT
DEUTSCHE BANK
DEUTSCHE BANKX

[Tom]

---

@Hoibai wrote:

The problem is, the first record is with {"Cdtr":{"Nm":"DEUTSCHE BANK"} .

The second record  is with '{"Cdtr":{"Nm":"VERGOELST GMBH"}'

according to the constant variables {"Cdtr":{"Nm":, each record in the file has a different value.

---

I don't understand what you mean be this.  Of course each observation has a different value.  But the PREFIX you are searching for looks exactly the same in both of those example values.  

{"Cdtr":{"Nm":"

Personally I avoid having to use regex if I can get the result I want with simpler functions.

data have;
  infile cards truncover;
  input str $200.;
cards4;
{"Cdtr":{"Nm":"DEUTSCHE BANK"}
{"Cdtr":{"Nm":"VERGOELST GMBH"}
{"ar:pacs.003.002.04":{"Cdtr":{"Nm":"DEUTSCHE BANK"},"CdtrAcct":{"Id":{"IBAN":"DE0111111111111111111100"}}
;;;;

data want;
  length cdtr_nm $60 ;
  set have;
  sp=index(str,'{"Cdtr":{"Nm":');
  if sp then cdtr_nm = dequote(substr(str,sp+length('{"Cdtr":{"Nm":')));
run;

[mkeintz]

Do they all have the form 

   "Cdtr":{"Nm":"XXX XXXX XXXXXX"}

where "XXX XXXX XXXXXX" is the desired result, and can have variable length?

If so, you can always skip the first 14 characters and drop the last 2 characters, which can be done with the SUBSTR and LENGTH functions:

data sample;
  string='"Cdtr":{"Nm":"DEUTSCHE BANK"}';
  new_string=substr(string,15,length(string)-16);

  put (_all_) (= /);
run;

Or if you want something more general, perhaps you can characterize the desired substring as the 5th word, where each double quote is treated as a word separator.  Then, as long as the desired expression is double-quoted, and it is preceded by two expressions that are also double quoted (i.e. preceded by 4 double quotes), you can do this: 

data sample;
  string='"Cdtr":{"Nm":"DEUTSCHE BANK"}';
  new_string=scan(string,5,'"');
  put (_all_) (= /);
run;