Introduce a blank/missing observation as first observation in existing dataset

[mgrasmussen]

Dear SAS experts

As a very simple example of my dataset, I would like to given a dataset like the following introduce a new observation as the 1st observation which only includes blanks/missing;

data have;
input Name $ Age num1 num2 num3;
datalines;
Maria 30 5 2 17
John 32 3 7 20
;
run;

It would be great to find a way to introduce the observation without having to specify "by hand" which variables are included in the dataset. I expect that I need to use some code which includes "then do" and "call missing (of _all_)", but I a cannot reach the desired code.

Can someone help?

Thank you

[PaigeMiller]

Shouldn't be hard to do, but what possible purpose is there in putting forth the effort to achieve a blank line in a data set?

[PeterClemmensen]

1) Why?

2) How:

data have;
input Name $ Age num1 num2 num3;
datalines;
Maria 30 5 2 17
John 32 3 7 20
;
run;

data want;
   set have;
   
   if _N_ = 1 then do;
      call missing(of _all_);
      output;
   end;
   
   output;
run;

[Kurt_Bremser]

With a little trickery with data step mechanics, it's easy:

data want;
if _n_ = 1 then output;
set have;
output;
run;

[FreelanceReinh · Accepted solution]

It's even easier:

data want;
output;
set have;
run;

Edit:

Explanation for @mgrasmussen:

1. In the first iteration of the DATA step the OUTPUT statement before the SET statement creates the blank observation, as desired. The variables from dataset HAVE exist in the program data vector due to the SET statement from the compilation phase, but have not been populated with values yet.
2. In the second (third, ...) iteration of the DATA step the OUTPUT statement writes the first (second, ...) observation of dataset HAVE to dataset WANT because variables read by the SET statement are automatically retained.
3. The iteration reading the last observation from dataset HAVE is not the last iteration of the DATA step. It is the SET statement failing to read beyond the last observation which terminates the DATA step. The OUTPUT statement before that final SET statement execution thus ensures that also the last observation of HAVE is written to dataset WANT.

[Kurt_Bremser]

Marvelous.

[SASJedi]

I don't know WHY you would want to do this, but it's fairly simple:

data have;
/* First iteration only, write out a row before reading data */
if _n_=1 then output;
input Name $ Age num1 num2 num3;
/* Write out a row after each data read */
output;
datalines;
Maria 30 5 2 17
John 32 3 7 20
;
run;