You are missing a step in your description.
Once you have the metadata available in a usable form you need to use that information to drive the process of reading the actual data. That process will vary depending on the software you are using to read in the CSV file. In SAS you would want to use the information to write a data step.
So first you need to decide what type of data step you want to generate. Then you can plan how to generate it from the metadata.
So for example for SASHELP.CARS you might want to generate a data step that looks like what I showed before:
data work.cars (label='2004 Car Data');
infile "cars.csv" dsd dlm='|' truncover;
length Make $13 Model $40 Type $8 Origin $6 DriveTrain $5
MSRP 8 Invoice 8 EngineSize 8 Cylinders 8 Horsepower 8 MPG_City 8
MPG_Highway 8 Weight 8 Wheelbase 8 Length 8
;
informat MSRP comma. Invoice comma. ;
format MSRP dollar8. Invoice dollar8. ;
label EngineSize='Engine Size (L)' MPG_City='MPG (City)'
MPG_Highway='MPG (Highway)' Weight='Weight (LBS)'
Wheelbase='Wheelbase (IN)' Length='Length (IN)'
;
input Make -- Length ;
run;
So if you have a dataset with MEMNAME MEMLABEL TYPE LENGTH INFORMAT FORMAT and LABEL you could use it to write such a program using a data step like this:
filename code temp;
data _null_;
file code ;
* Write data statement and INFILE statement ;
put 'data ' memname '(label=' memlabel :$quote. ')'
/ ' infile "myfile.csv" dsd truncover firstobs=2;'
;
* Write LENGTH statement ;
put 'length ' @;
do p=1 to nobs;
set metadata point=p nobs=nobs;
put name @;
if type='String' then put '$' @;
put length @;
end;
put ';' ;
* Write informat statement ;
put 'informat ' @;
do p=1 to nobs;
set metadata point=p ;
if informat ne ' ' then put name informat @;
end;
put ';' ;
* Write format statement ;
put 'format ' @;
do p=1 to nobs;
set metadata point=p ;
if format ne ' ' then put name format @;
end;
put ';' ;
* Write label statement ;
put 'label' @;
do p=1 to nobs;
set metadata point=p ;
if label ne ' ' then put name label :$quote. @;
end;
put ';' ;
* Write input statement ;
p=1;
set metadata point=p;
put 'input ' name '-- ' @ ;
p=nobs;
set metadata point=p;
put name ';' ;
* Write run statement ;
put 'run;' ;
run;
And once you have the code in a file you can use %INCLUDE to run it.
%include code / source2;
Or perhaps you would rather generate a data step that looks like this;
data work.cars (label='2004 Car Data');
infile "cars.csv" dsd dlm='|' truncover;
attrib Make length=$13 ;
attrib Model length=$40 ;
attrib Type length=$8 ;
attrub Origin length=$6;
attrib DriveTrain length=$5;
attrib MSRP length=8 informat=comma. format=dollar8. ;
attrib Invoice length=8 ;
attrib EngineSize length=8 label='Engine Size (L)' ;
/* fill in the rest of them */
input Make -- Length ;
run;
Which would be simpler to create via a data step like
filename code temp;
data _null_;
file code ;
set metadata end=eof;
if _n_=1 then do;
firstvar=name;
retain firstvar ;
put
'data ' memname '(label=' memlabel :$quote. ');'
/' infile "myfile.csv" dsd truncover firstobs=2;'
;
end;
put 'attrib ' name length= @;
if format ne ' ' then put format= @;
if informat ne ' ' then put informat= @;
if label ne ' ' then put label = :$quote. @;
put ';' ;
if eof then put
' input ' firstvar '-- ' name ';'
/ 'run;'
;
run;
You will need to work out the details. For example if you have TYPE and LENGTH as two variables then you need to have logic in the code generation step to convert that in the SAS syntax you need to generate. Like I showed in the first example
if type='String' then put '$' @;
put length @;
But if you have length with values like $6 and 8 then you can just use the value directly as the code snippet you need to generate, like I did in the second example.
And if you are trying to read the CSV with python or R or some other future language you would need different code generation.
