If then else character variable

[r_trivedi]

Hi!

I'm using SAS 9.4 and I'm trying to recode a variable called PHQ_9_Severity into "Normal" "Mild" "Moderate" and "Severe". The original data set has "Normal" "Mild" "Moderate" "Moderately Severe" and "Severe". I'm trying to make "Moderately Severe" and "Severe" output as "Severe". When I run this code, it prints all of my observations but changes all of the observations that are "Mild" "Moderately Severe" and "Severe" to "Severe" and leaves "Normal" as is leaving me with only two groups.

data nallergy.phq;
set nallergy.phq9;
if PHQ_9_Severity = "Mild" then PHQ9Severity="Mild";
if PHQ_9_Severity = "Moderate" then PHQ9Severity="Moderate";
if PHQ_9_Severity = "Normal" then PHQ9Severity="Normal";
else PHQ9Severity = "Severe";
run;

I can't figure out what I'm doing wrong. Thank you in advance!!

[VDD]

have you tried using compress and upcase to the variables to confirm that you match case sensitivity and that there are not trailing spaces?

posting sample data in a data step helps because we don't see what you are looking at based on your statement.

[PaigeMiller · Accepted solution]

You need ELSE in a number of places, so that the last line only executes if all the other conditions fail. If you only put ELSE at the end, you get incorrect results.

if PHQ_9_Severity = "Mild" then PHQ9Severity="Mild";
else if PHQ_9_Severity = "Moderate" then PHQ9Severity="Moderate";
else if PHQ_9_Severity = "Normal" then PHQ9Severity="Normal";
else PHQ9Severity = "Severe";

[ballardw]

You may not even need a new variable. Consider:

proc format library=work;
value $sev
"Normal" ="Normal"
"Mild"   ="Mild"
"Moderate"="Moderate" 
"Moderately Severe","Severe"="Severe"
;
run;


proc freq data=nalergy.phq9;
   table PHQ_9_Severity ;
   format PHQ_9_Severity $sev.;
run;

Groups created by format levels are honored by almost all of the SAS analysis, reporting or graphing procedures.

One big advantage of custom format like this is that you do not need to keep adding variable. If latter you want to analyze on three groups such as "Normal" "Mild/Moderate" and "Moderately Severe/Sever" or "Normal" "Mild" "Moderate/Moderately Severe" "Severe" you only need to create a new format.

Another advantage is if you have multiple variables that have the same coding scheme you can apply the format to those variables as well with a single format statement. Or if you need the different levels in analysis then one format to one variable and a different to others.