How to use Proc Freq to get riskdifference confidence limit in the output dataset

[chillywind]

I want to get the newcombe confidence limit for future use. It shows in the output. But in the outdata there is no such variable. 

proc freq data=indata;
table trt*endpoint/ chisq riskdiff(cl=( newcombe ) correct );
output out=outdata CHISQ RDIF1 ;
run;

[PGStats]

Add the statement 

ods output PdiffCLs=clStats;

to create dataset clStats with the confidence limits.

(untested)

[art297]

You can get that using ods output. Here is an example showing how to find the various tables that capture the output from any proc, along with how to "grab" that output:

data class;
  set sashelp.class;
  if age gt 14 then age=2;
  else age=1;
  do i=1 to 20;
    output;
  end;
  
run;
ods trace on;
proc freq data=class;
  table sex*age/ chisq riskdiff(cl=( newcombe ) correct );
  output out=outdata CHISQ RDIF1 ;
run;
ods trace off;

*ods output RiskDiffCol1=col1;
*ods output RiskDiffCol2=col2;
ods output PdiffCLs=pdiff;
proc freq data=class;
  table sex*age/ chisq riskdiff(cl=( newcombe ) correct );
  output out=outdata CHISQ RDIF1 ;
run;

Art, CEO, AnalystFinder.com