How to simulate two parameters with correlation of 0.8

[superbug]

I want to simulate two parameters a* and b satisfying the following conditions. How should I simulate these two parameter so that the correlation of them is 0.8. Thanks much for the help!

[PaigeMiller]

https://blogs.sas.com/content/iml/2017/09/25/simulate-multivariate-normal-data-sas-simnormal.html

[superbug]

@PaigeMiller 

Thanks much for the information.

Flowing example you provided, I made up my outcorr data, which looks like following table

I use the following code 

proc import datafile="....\outcorr.csv"
dbms=csv out=outcorr replace; run;

%let N = 60;            /* sample size */
%let NumSamples = 100;  /* number of samples */
proc simnormal data=work.outcorr outsim=SimMVN
               numreal = %sysevalf(&N*&NumSamples) 
               seed = 12345;          /* random number seed */
   var a b;
run;

However, there is following error message

I am seeing the "outcorr" data has been normally read in. Do you have any idea of what caused this error message?

Again thanks much!

[PaigeMiller]

How was OUTCORR created? Can you show us (screen capture is okay) OUTCORR?

[superbug]

@PaigeMiller 

I manually created outcorr.csv, which looks like following

[PaigeMiller]

I will throw this question over to @Rick_SAS to see if he has any ideas why you are getting an error.

[superbug]

@PaigeMiller 

Thanks!

I'll keep you updated once I hear from him. 

[Rick_SAS]

You can either use a TYPE=CORR or a TYPE=COV matrix as an input matrix to PROC SIMNORMAL. Here is both ways:

data outcorr(type=CORR);
input _TYPE_ $ 1-4 _NAME_ $ 5-6 a b;
datalines ;
MEAN    0      0
STD     0.1225 2
CORR a  1      0.8
CORR b  0.8    1
run;

proc simnormal data=work.outcorr outsim=SimMVN
               numreal = %sysevalf(&N*&NumSamples) 
               seed = 12345;          /* random number seed */
   var a b;
run;

Or (the harder way, because you have to form the covariance matrix yourself😞

data outcorr(type=COV);
input _TYPE_ $ 1-4 _NAME_ $ 5-6 a b;
datalines ;
MEAN    0      0
COV  a  0.015  0.196
COV  b  0.196  4
run;

%let N = 60;            /* sample size */
%let NumSamples = 100;  /* number of samples */
proc simnormal data=work.outcorr outsim=SimMVN
               numreal = %sysevalf(&N*&NumSamples) 
               seed = 12345;          /* random number seed */
   var a b;
run;

I want to make sure that the OP wants bivariate normal data. The initial post states

a ~ (0, 0.1225)

b ~ (0,2)

I do not know what that notation means. People seem to be interpreting it as

a ~ N(0, 0.1225)

b ~ N(0,2)

which seems likely, but worth verifying with the instructor of the class.

[superbug]

@Rick_SAS 

Thank you SOOO much for your quick response!

Yes, your code worked. The standard expression should be the following as you pointed out

a ~ N(0, 0.1225)

b ~ N(0, 2)

Could you please explain how did you get the numbers in the covariance matrix as following? 

COV  a  1.915  0.3873
COV  b  0.3873 4.321

[Rick_SAS · Accepted solution]

I'm very sorry. That was a mistake on my part because I copied/pasted from another source.

From your follow-up post, I assume that N(0,2) means "mean=0 and stdDev=2." If so, the correct covariance matrix should be

COV  a  0.015  0.196
COV  b  0.196  4

which is the matrix in the second part of the problem. I will edit my solution. Thanks.

[superbug]

@Rick_SAS 

Thank you!

when I changed it to

COV  a  0.015  0.196
COV  b  0.196  4

and run the code, it has the following error message

[superbug]

@Rick_SAS 

Please ignore my last message. the error message resolved.

I very much appreciate your help and expertise. Again thanks much! 

[PaigeMiller]

---

@Rick_SAS wrote:

Here is the correct DATA step to create the input matrix for PROC SIMNORMAL:

data outcorr(type=COV);
input _TYPE_ $ 1-4 _NAME_ $ 5-6 a b;
datalines ;
MEAN    0      0
STD     0.1225 2
COV  a  1.915  0.3873
COV  b  0.3873 4.321
run;

%let N = 60;            /* sample size */
%let NumSamples = 100;  /* number of samples */
proc simnormal data=work.outcorr outsim=SimMVN
               numreal = %sysevalf(&N*&NumSamples) 
               seed = 12345;          /* random number seed */
   var a b;
run;

I want t make sure that the OP wants bivariate normal data. The initial post states

a ~ (0, 0.1225)

b ~ (0,2)

I do not know what that notation means. People seem to be interpreting it as

a ~ N(0, 0.1225)

b ~ N(0,2)

which seems likely, but worth verifying with the instructor of the class.

---

Well, that seems like an obvious error to me, now that you have pointed it out. COV matrix not CORR matrix. Thanks, @Rick_SAS 

[Reeza]

Do you have SAS IML? If so, this could this be considered a multivariate normal distribution?
https://blogs.sas.com/content/iml/2011/01/12/sampling-from-the-multivariate-normal-distribution.html
Note the bottom note about using a correlation matrix instead of a covariance matrix.

[superbug]

@Reeza 

Thanks much!

I don't have SAS IML.

I don't know how to do this step as well.