The hard part is to get the list of dataset and variables.
But let's do the easy part first.
Just set all of the observations from all of the dataset, only keeping the date variables.
data want;
retain _max_date ;
set Visit (keep=visdat) TestA (keep=testadat) TestC(keep=testcdat) Vs(keep=vsdat) end=eof;
_max_date = max(of _numeric_);
if eof ;
put _max_date=;
keep _max_date;
format _max_date date9.;
run;
Now if you had a dataset with a structure like:
data dates ;
input libname :$8. memname :$32. name :$32. ;
cards;
WORK VISIT VISDAT
WORK TESTA TESTADAT
WORK TESTB TESTBDAT
WORK VS VSDAT
;
You could generate that SET statement with a simple data step.
filename code temp;
data _null_;
set dates end=eof;
by libname memname ;
file code;
if _n_=1 then put 'set ' @;
if first.memname then put libname +(-1) '.' memname '(keep=' @;
put name @;
if last.memname then put ') ' @ ;
if eof then put 'end=eof;' ;
run;
So then just replace the SET statement in the previous code with :
%include code / source2;
Now how can you get the list of variables?
Use PROC CONTENTS to get a list of ALL of the variables in all of the datasets in your library. Then just filter to the ones that have date type formats attached to them.
So your whole program might look like this:
libname mylib 'directory with SAS datasets';
proc contents data=mylib._all_ noprint out=contents; run;
filename code temp;
data _null_;
set contents end=eof;
where 'date' = fmtinfo('cat',format);
by libname memname ;
file code;
if _n_=1 then put 'set ' @;
if first.memname then put libname +(-1) '.' memname '(keep=' @;
put name @;
if last.memname then put ') ' @ ;
if eof then put 'end=eof;' ;
run;
data want;
retain _max_date ;
%include code / source2;
_max_date = max(of _numeric_);
if eof ;
put _max_date=;
keep _max_date;
format _max_date date9.;
run;
