How do I split initials by dots

[Gerrit65]

I need to produce a SAS-dataset in which the initials of the client have to be splitted by dots.

Input SAS dataset		Output SAS dataset must be like this
Initials	Last_name		Initials must be	Last_name
K	Jansen		K.	Jansen
JL	de Vries		J.L.	de Vries
GJPG	Boersma		G.J.P.G.	Boersma

[kiranv_]

please show sample input data and output data you want to have . Many of us will not open attachments for various issues like virus etc.

[Kurt_Bremser]

data have;
input initials :$5. last_name :$20.;
cards;
K Jansen
JL deVries
GJPG Boersma
;
run;

data want;
length initials $10;
set have (rename=(initials=_initials));
do i = 1 to length(_initials);
  initials = trim(initials) !! substr(_initials,i,1) !! '.';
end;
drop i _initials;
run;

proc print data=want noobs;
run;

Note the way I presented example data in a data step for easy recreation (needs only copy/paste and run).

Also note how I took care of the increasing length of the initials variable.

The result:

             last_
initials     name

K.          Jansen 
J.L.        deVries
G.J.P.G.    Boersma

[Gerrit65]

Thanks Kurt!! It works excellent!!!

[Haikuo]

PRX seems handy:

data have;
infile cards truncover ;
input var $ 100.;
newvar=prxchange('s/(\w)/$1./',-1,var);
cards;
K
Jansen
JL
de Vries
JPG
Boersma
;