Hello @DaveKerr and welcome to the SAS Support Communities!
In general, with two numeric variables (e.g., age and income) you will get a convex curve of eligible pairs of values (see PROC SGPLOT step in the code example below). So you'll need to define some sort of optimality criterion to determine the "optimal" point of the curve, e.g., minimize an objective function. Unless you have advanced tools (such as SAS/OR) available, you may need to categorize one of the two variables. Then you could obtain the relevant cutoff value for the other variable in each of the cumulative categories. In the case of age (assuming integer values, say, 18, 19, 20, ...), using the individual age values (as cutoffs) should be feasible. So you would determine the cutoff value for income in each of the groups age=18, age<=19, age<=20 and so on, i.e., the income X(age) such that the subset "income<=X(age)" in the respective group just comprises 5% of the entire dataset (which might exclude a few young age groups due to their size). Finally, apply the optimality criterion to those pairs of age and income cutoff values.
Below is an example. For simplicity I assume non-missing values for the relevant numeric variables (AGE and INCOME). In the presence of missing values you would need to exclude affected observations (since otherwise a condition such as age<=20 would also select observations with a missing age value).
/* Create sample data for demonstration */
data have;
call streaminit(3141592);
do i=1 to 100000;
age=rand('integer',18,65);
income=round(rand('lognormal',9.117+0.0531*age,age/240),0.01);
output;
end;
run;
/* Store 5% of the number of obs. in HAVE in macro variable N5P */
data _null_;
call symputx('n5p',ceil(0.05*n));
stop;
set have nobs=n;
run;
%put &=n5p;
/* Create view with income values of cumulative age groups */
proc sql;
create view vtemp as
select a.age, b.income
from (select distinct age from have a) left join have b
on b.age<=a.age
order by age, income;
quit;
/* Determine income cutoff value for each group (if &N5P obs. are available)
and compute objective function */
data opt;
do _n_=1 by 1 until(last.age);
set vtemp;
by age;
if _n_=&n5p then do;
c=log(income)**2+(age/20)**2; /* define your own objective function */
output;
end;
end;
run;
/* Optional: Visualize relationship between cutoff values */
proc sgplot data=opt;
series x=age y=income;
run;
/* Determine the combination of cutoff values minimizing the objective function */
proc summary data=opt;
var c;
output out=want(drop=_:) minid(c(age income))=opt_age opt_income;
run;
proc print data=want;
run;
/* Optional: Perform the selection */
data sel(drop=opt_:);
if _n_=1 then set want;
set have;
if age<=opt_age & income<=opt_income;
run;
