Hello everybody!
I was wondering if somebody could help me with my problem.
Basically I have a SAS macro variable which is a list of the variables that are present in a SAS data set and I am cycling through those variables and would like to say cap those variables that are > 254.
Here is the sample code
..... blah-blah-blah... the list of the variable names are put into the sas macro variable called modelvars.
%macro get_capped();
data a;
set b (obs=100);
%let j = 1;
%do %until (%scan(&modelvars.,&j,%str( ))= %str());
%let var=%upcase(%scan(&modelvars.,&j,%str( )));
%if &var. > 254 %then &var. = 254;
%let j = %eval(&j +1);
%end;
run;
%mend get_capped;
%get_capped;
The RED code is the one that I am stuck on. I know that the variable name resolved to TEXT, but how do I make SAS compiler treat that text as if it was the name of the actual variable in the data set and then cap that variable?
Any help would be greatly appreciated!
Thanks!
On the one hand, you are very close to having a working program. Getting rid of two % should make it work:
if &var. > 254 then &var. = 254;
On the other hand, this could be solved much more simply, without the need to define a macro. Consider:
data a;
set b (obs=100);
array cap_me {*} &modelvars.;
do _i_=1 to dim(cap_me);
if cap_me{_i_} > 254 then cap_me{_i_} = 254;
end;
run;
Good luck.
On the one hand, you are very close to having a working program. Getting rid of two % should make it work:
if &var. > 254 then &var. = 254;
On the other hand, this could be solved much more simply, without the need to define a macro. Consider:
data a;
set b (obs=100);
array cap_me {*} &modelvars.;
do _i_=1 to dim(cap_me);
if cap_me{_i_} > 254 then cap_me{_i_} = 254;
end;
run;
Good luck.
Thank you very much for your help!
Hi,
try the code below:
%macro get_capped();
data a;
set b (obs=100);
%let j = 1;
%do %until (%scan(&modelvars.,&j,%str( ))= %str());
%let var=%upcase(%scan(&modelvars.,&j,%str( )));
if &var. > 254 then &var. = 254;
%let j = %eval(&j +1);
%end;
run;
%mend get_capped;
%get_capped;
Are you ready for the spotlight? We're accepting content ideas for SAS Innovate 2025 to be held May 6-9 in Orlando, FL. The call is open until September 25. Read more here about why you should contribute and what is in it for you!
Learn how use the CAT functions in SAS to join values from multiple variables into a single value.
Find more tutorials on the SAS Users YouTube channel.