cancel
Turn on suggestions
Auto-suggest helps you quickly narrow down your search results by suggesting possible matches as you type.
Showing results for 
Search instead for 
Did you mean: 
BookmarkSubscribeRSS Feed
☑ This topic is solved. Need further help from the community? Please sign in and ask a new question.
RooRoo
Fluorite | Level 6 RooRoo
Fluorite | Level 6
Go to Solution

First page is blank when using page break, define option PAGE, and LINE command in compute block

Posted 2 weeks ago (1013 views)

Hello eveyone!

 

I use SAS Enterprise Guide 8.5 with and have been struggling with the following issue for a few days.

 

I run the code below:

DATA AAA;
	SET SASHELP.CARS;
	PAGE_NO = FLOOR((_n_-1)/15)+1;
RUN;


ODS RTF(ID=INDA) FILE= "\\app01.icrc.local\Share\Projects\ROX_795_SC-332A\Biostatistics\Prog\A.rtf" CONTENTS=YES STARTPAGE=YES TOC_DATA;
PROC REPORT DATA=AAA(obs=100);
	COLUMNS PAGE_NO Make Model Type Origin DriveTrain MSRP Invoice EngineSize Cylinders Horsepower MPG_City MPG_Highway;
	DEFINE PAGE_NO / ORDER NOPRINT contents="";
	DEFINE Make / ORDER NOPRINT;
	DEFINE Model / 		DISPLAY ID STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Type / 		DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Origin / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE DriveTrain / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MSRP / 		DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Invoice / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN} contents="" PAGE;
	DEFINE EngineSize / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Cylinders / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Horsepower / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MPG_City / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MPG_Highway /DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};

	COMPUTE BEFORE Make;
		LINE @1 " ";
		LINE @1 Make $16.;
		LINE @1 " ";
	ENDCOMP;

	break before page_no / page contents="";

	compute after _page_;
		line "Some text";
		line "Some other text";
	endcomp;

	compute after;
		line "End of Table";
	endcomp;


RUN;
ODS RTF(ID=INDA) CLOSE;

My purpose is to produce a report:

1) With page breaks (hence the line break before page_no / page);

2) With footnotes in every page and a messege in the end of table;

3) With page breakes before the column Invoice (hence DEFINE Invoice / ... PAGE);

4) With a line before every new group (hence the COMPUTE BEFORE Make block);

 

The problem is that the generated report has the first page empty:

Bild1.png

Everything else works fine.

 

I tried some approaches. So, replacing break before page_no / page with break after page_no / page solves this problem, but creates other ones (for example empty pages in the end).

Also, deleting the COMPUTE BEFORE Make block make thing better. But unfortunately, the line before every group is required.

Of course reducing column width (so that all columns fit in one page) helps too, but in real projects we often have reports with many columns.

 

I hope someone could help me with good advice. Thanks in advance!

0 Likes
Reply
1 ACCEPTED SOLUTION

Accepted Solutions
Ksharp
Super User Ksharp
Super User

Re: First page is blank when using page break, define option PAGE, and LINE command in compute block

Posted a week ago (823 views)  |   In reply to RooRoo
"First, the line 'End of Table' is seen on the two last pages instead of only the last one."
Then using 
ODS TEXT='xxxxxxxx' ;
to generate the last line  'End of Table' at end of report, and get rid of 
%if &level.=&last. %then %do;
                line " ";
line "End of Table";
%end;
 
 
 
"Besides, for groups with few entries thewe will be pages with too much empty space, whereas groups with too many entries would cause other problems. This why controlled page breaks are important here."
You could use STARTPAGE=NO to get compact layout.
And you could also combine the page breaks and macro together.
DATA AAA;
	SET SASHELP.CARS;
RUN;
proc sort data=AAA;
by Make;
run;
data AAA;
 set AAA;
 PAGE_NO = FLOOR((_n_-1)/15)+1;
run;


proc sort data=AAA;
by Make;
run;
proc freq data=AAA noprint;
table Make/out=levels;
run;







%macro report(level=);
PROC REPORT DATA=AAA nowd;
where Make="&level.";
	COLUMNS PAGE_NO Make Model Type Origin DriveTrain MSRP Invoice EngineSize Cylinders Horsepower MPG_City MPG_Highway;
	DEFINE PAGE_NO / ORDER NOPRINT;
	DEFINE Make / ORDER NOPRINT;
	DEFINE Model / 		DISPLAY ID STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Type / 		DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Origin / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE DriveTrain / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MSRP / 		DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Invoice / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN}  PAGE;
	DEFINE EngineSize / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Cylinders / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Horsepower / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MPG_City / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MPG_Highway /DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};

	COMPUTE BEFORE Make;
		LINE @1 " ";
		LINE @1 Make $16.;
		LINE @1 " ";
	ENDCOMP;


	compute after Make;
		line "Some text";
		line "Some other text";
	endcomp;
break after page_no / page contents="";
RUN;
%mend;



ODS RTF(ID=INDA) FILE= "c:\temp\A.rtf" CONTENTS=YES STARTPAGE=NO TOC_DATA;
data _null_;
 set levels;
 call execute(catt('%report(level=',Make,')'));
run;
ods text='End of Table';
ODS RTF(ID=INDA) CLOSE;
Ksharp_0-1741829379029.png

 

 

View solution in original post

Reply
24 REPLIES 24
Ksharp
Super User Ksharp
Super User

Re: First page is blank when using page break, define option PAGE, and LINE command in compute block

Posted a week ago (968 views)  |   In reply to RooRoo
That is because you used PAGE option.
Get rid of this option:
DEFINE Invoice / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN} contents="" PAGE;
--->
DEFINE Invoice / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN} ;
Reply
Ksharp
Super User Ksharp
Super User

Re: First page is blank when using page break, define option PAGE, and LINE command in compute block

Posted a week ago (970 views)  |   In reply to RooRoo

Or you could try wide layout by using "options orientation=" . And delete "ID" and "PAGE" option in DEFINE statement.

options orientation=landscape;
ODS RTF(ID=INDA) FILE=.........................

Reply
RooRoo
Fluorite | Level 6 RooRoo
Fluorite | Level 6

Re: First page is blank when using page break, define option PAGE, and LINE command in compute block

Posted a week ago (935 views)  |   In reply to Ksharp
Thanks for your reply!

Unfortunately, it wouldn't be enough to change the orientation because, as mentioned in the post, sometimes we have many columns, so that even the landscape orientation is not enough.

And as all the columns don't fit in one page, removing ID and PAGE options is not a good option, without them the output is pretty chaotic.

As is, ID and PAGE options work just fine, but only adding extra lines with "COMPUTE AFTER Make" block creates the issue, and only on the first page.
0 Likes
Reply
Ksharp
Super User Ksharp
Super User

Re: First page is blank when using page break, define option PAGE, and LINE command in compute block

Posted a week ago (923 views)  |   In reply to RooRoo

Interesting. You could try BY statement instead of PAGE option.

 

DATA AAA;
	SET SASHELP.CARS;
	PAGE_NO = FLOOR((_n_-1)/15)+1;
RUN;

option nobyline;
ODS RTF(ID=INDA) FILE= "c:\temp\A.rtf" CONTENTS=YES STARTPAGE=YES TOC_DATA;
PROC REPORT DATA=AAA(obs=100);
by PAGE_NO;
	COLUMNS /* PAGE_NO */ Make Model Type Origin DriveTrain MSRP Invoice EngineSize Cylinders Horsepower MPG_City MPG_Highway;
/*	DEFINE PAGE_NO / ORDER NOPRINT ;*/
	DEFINE Make / ORDER NOPRINT;
	DEFINE Model / 		DISPLAY ID STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Type / 		DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Origin / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE DriveTrain / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MSRP / 		DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Invoice / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN}  PAGE;
	DEFINE EngineSize / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Cylinders / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Horsepower / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MPG_City / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MPG_Highway /DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};

	COMPUTE BEFORE Make;
		LINE @1 " ";
		LINE @1 Make $16.;
		LINE @1 " ";
	ENDCOMP;

/*	break before page_no / page contents="";*/

	compute after _page_;
		line "Some text";
		line "Some other text";
	endcomp;

	compute after;
		line "End of Table";
	endcomp;


RUN;
ODS RTF(ID=INDA) CLOSE;

Ksharp_0-1741765308689.png

 

Reply
RooRoo
Fluorite | Level 6 RooRoo
Fluorite | Level 6

Re: First page is blank when using page break, define option PAGE, and LINE command in compute block

Posted a week ago (901 views)  |   In reply to Ksharp

Thanks for the idea!

 

But looks like it doesn't work as desired.

First, it produces the line "End of Table" on every page instead of the actual end of the table.

Second, on some pages data appear even after the footnotes.

pic.png

0 Likes
Reply
Ksharp
Super User Ksharp
Super User

Re: First page is blank when using page break, define option PAGE, and LINE command in compute block

Posted a week ago (896 views)  |   In reply to RooRoo

OK. you could make a macro to workaround with this question.

DATA AAA;
	SET SASHELP.CARS(obs=100);
RUN;
proc sort data=AAA;
by Make;
run;
proc freq data=AAA noprint;
table Make/out=levels;
run;
data _null_;
 set levels;
 call symputx('last',Make);
run;






%macro report(level=);
PROC REPORT DATA=AAA;
where Make="&level.";
	COLUMNS  Make Model Type Origin DriveTrain MSRP Invoice EngineSize Cylinders Horsepower MPG_City MPG_Highway;
	DEFINE Make / ORDER NOPRINT;
	DEFINE Model / 		DISPLAY ID STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Type / 		DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Origin / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE DriveTrain / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MSRP / 		DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Invoice / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN}  PAGE;
	DEFINE EngineSize / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Cylinders / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Horsepower / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MPG_City / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MPG_Highway /DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};

	COMPUTE BEFORE Make;
		LINE @1 " ";
		LINE @1 Make $16.;
		LINE @1 " ";
	ENDCOMP;


	compute after _page_;
		line "Some text";
		line "Some other text";
	endcomp;

%if &level.=&last. %then %do;
	compute after;
		line "End of Table";
	endcomp;
%end;
RUN;
%mend;



ODS RTF(ID=INDA) FILE= "c:\temp\A.rtf" CONTENTS=YES STARTPAGE=YES TOC_DATA;
data _null_;
 set levels;
 call execute(catt('%report(level=',Make,')'));
run;
ODS RTF(ID=INDA) CLOSE;

Ksharp_0-1741768876498.png

 

Reply
Ksharp
Super User Ksharp
Super User

Re: First page is blank when using page break, define option PAGE, and LINE command in compute block

Posted a week ago (892 views)  |   In reply to RooRoo

"compute after " would execute before "compute after _page_" , you would get reverse order of text , try to combine them together.

DATA AAA;
	SET SASHELP.CARS(obs=200);
RUN;
proc sort data=AAA;
by Make;
run;
proc freq data=AAA noprint;
table Make/out=levels;
run;
data _null_;
 set levels;
 call symputx('last',Make);
run;






%macro report(level=);
PROC REPORT DATA=AAA nowd;
where Make="&level.";
	COLUMNS  Make Model Type Origin DriveTrain MSRP Invoice EngineSize Cylinders Horsepower MPG_City MPG_Highway;
	DEFINE Make / ORDER NOPRINT;
	DEFINE Model / 		DISPLAY ID STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Type / 		DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Origin / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE DriveTrain / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MSRP / 		DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Invoice / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN}  PAGE;
	DEFINE EngineSize / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Cylinders / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Horsepower / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MPG_City / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MPG_Highway /DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};

	COMPUTE BEFORE Make;
		LINE @1 " ";
		LINE @1 Make $16.;
		LINE @1 " ";
	ENDCOMP;


	compute after _page_;
		line "Some text";
		line "Some other text";

%if &level.=&last. %then %do;
                line " ";
		line "End of Table";
%end;
	endcomp;

RUN;
%mend;



ODS RTF(ID=INDA) FILE= "c:\temp\A.rtf" CONTENTS=YES STARTPAGE=YES TOC_DATA;
data _null_;
 set levels;
 call execute(catt('%report(level=',Make,')'));
run;
ODS RTF(ID=INDA) CLOSE;

Ksharp_0-1741769762522.png

 

Reply
RooRoo
Fluorite | Level 6 RooRoo
Fluorite | Level 6

Re: First page is blank when using page break, define option PAGE, and LINE command in compute block

Posted a week ago (854 views)  |   In reply to Ksharp

Thanks for your effort!

 

But there's still some issues.

First, the line 'End of Table' is seen on the two last pages instead of only the last one.

Besides, for groups with few entries thewe will be pages with too much empty space, whereas groups with too many entries would cause other problems. This why controlled page breaks are important here.

0 Likes
Reply
ballardw
Super User ballardw
Super User

Re: First page is blank when using page break, define option PAGE, and LINE command in compute block

Posted a week ago (823 views)  |   In reply to RooRoo
@RooRoo wrote:

Thanks for your effort!

 

But there's still some issues.

First, the line 'End of Table' is seen on the two last pages instead of only the last one.

Besides, for groups with few entries thewe will be pages with too much empty space, whereas groups with too many entries would cause other problems. This why controlled page breaks are important here.

Hint: when trying to create an exact appearance then provide an example of what the desired appearance actually is, as in a manually created document. That way we can tell if the result of a code suggestion does not actually meet requirement. Without a clear requirement you will get many "close but not quite" because we don't know the actual requirement.

Reply
RooRoo
Fluorite | Level 6 RooRoo
Fluorite | Level 6

Re: First page is blank when using page break, define option PAGE, and LINE command in compute block

Posted a week ago (777 views)  |   In reply to ballardw
Yes, you are totally right, I should have provided the desired appearence as describing such things only with words can be quite confusing 🙂
0 Likes
Reply
Ksharp
Super User Ksharp
Super User

Re: First page is blank when using page break, define option PAGE, and LINE command in compute block

Posted a week ago (824 views)  |   In reply to RooRoo
"First, the line 'End of Table' is seen on the two last pages instead of only the last one."
Then using 
ODS TEXT='xxxxxxxx' ;
to generate the last line  'End of Table' at end of report, and get rid of 
%if &level.=&last. %then %do;
                line " ";
line "End of Table";
%end;
 
 
 
"Besides, for groups with few entries thewe will be pages with too much empty space, whereas groups with too many entries would cause other problems. This why controlled page breaks are important here."
You could use STARTPAGE=NO to get compact layout.
And you could also combine the page breaks and macro together.
DATA AAA;
	SET SASHELP.CARS;
RUN;
proc sort data=AAA;
by Make;
run;
data AAA;
 set AAA;
 PAGE_NO = FLOOR((_n_-1)/15)+1;
run;


proc sort data=AAA;
by Make;
run;
proc freq data=AAA noprint;
table Make/out=levels;
run;







%macro report(level=);
PROC REPORT DATA=AAA nowd;
where Make="&level.";
	COLUMNS PAGE_NO Make Model Type Origin DriveTrain MSRP Invoice EngineSize Cylinders Horsepower MPG_City MPG_Highway;
	DEFINE PAGE_NO / ORDER NOPRINT;
	DEFINE Make / ORDER NOPRINT;
	DEFINE Model / 		DISPLAY ID STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Type / 		DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Origin / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE DriveTrain / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MSRP / 		DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Invoice / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN}  PAGE;
	DEFINE EngineSize / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Cylinders / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Horsepower / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MPG_City / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MPG_Highway /DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};

	COMPUTE BEFORE Make;
		LINE @1 " ";
		LINE @1 Make $16.;
		LINE @1 " ";
	ENDCOMP;


	compute after Make;
		line "Some text";
		line "Some other text";
	endcomp;
break after page_no / page contents="";
RUN;
%mend;



ODS RTF(ID=INDA) FILE= "c:\temp\A.rtf" CONTENTS=YES STARTPAGE=NO TOC_DATA;
data _null_;
 set levels;
 call execute(catt('%report(level=',Make,')'));
run;
ods text='End of Table';
ODS RTF(ID=INDA) CLOSE;
Ksharp_0-1741829379029.png

 

 
Reply
Ksharp
Super User Ksharp
Super User

Re: First page is blank when using page break, define option PAGE, and LINE command in compute block

Posted a week ago (811 views)  |   In reply to RooRoo

And I also found you could get job done with your original code by this one:

 

DATA AAA;
	SET SASHELP.CARS;
RUN;
proc sort data=AAA;
by Make;
run;
data AAA;
 set AAA;
 PAGE_NO = FLOOR((_n_-1)/15)+1;
run;




ODS RTF(ID=INDA) FILE= "c:\temp\A.rtf" CONTENTS=YES STARTPAGE=YES TOC_DATA;
PROC REPORT DATA=AAA(obs=100);
	COLUMNS PAGE_NO Make Model Type Origin DriveTrain MSRP Invoice EngineSize Cylinders Horsepower MPG_City MPG_Highway;
	DEFINE PAGE_NO / ORDER NOPRINT contents="";
	DEFINE Make / ORDER NOPRINT;
	DEFINE Model / 		DISPLAY ID STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Type / 		DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Origin / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE DriveTrain / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MSRP / 		DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Invoice / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN} contents="" PAGE;
	DEFINE EngineSize / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Cylinders / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE Horsepower / DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MPG_City / 	DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};
	DEFINE MPG_Highway /DISPLAY STYLE(COLUMN)={CELLWIDTH=1IN};

	COMPUTE BEFORE Make;
		LINE @1 " ";
		LINE @1 Make $16.;
		LINE @1 " ";
	ENDCOMP;

	break after page_no / page contents="";

	compute after _page_;
		line "Some text";
		line "Some other text";
	endcomp;


RUN;
ods text='End of Table';

ODS RTF(ID=INDA) CLOSE;

Ksharp_0-1741829782496.png

 

Ksharp_1-1741829807909.png

 

Reply
RooRoo
Fluorite | Level 6 RooRoo
Fluorite | Level 6

Re: First page is blank when using page break, define option PAGE, and LINE command in compute block

Posted a week ago (766 views)  |   In reply to Ksharp

That works fine, thank you!

But I just discovered something strange. I noticed there's two "first" pages. All further pages are numerated correctly.

Besides, in TOC there's unwanted Table1 which appears when using break after page_no / page contents=""; instead of break before page_no / page contents="";

 

Do you have any ideas?


Unbenannt.pngUnbenannt2.png

0 Likes
Reply
Ksharp
Super User Ksharp
Super User

Re: First page is blank when using page break, define option PAGE, and LINE command in compute block

Posted a week ago (754 views)  |   In reply to RooRoo

Actually I did not get any problem.

Ksharp_0-1741857572781.png

 

Ksharp_1-1741857601748.png

 

 

But if you really have this problem , you can use ~{thispage} to get the page number:

option nodate nonumber;
ODS RTF(ID=INDA) FILE= "c:\temp\A.rtf" CONTENTS=YES STARTPAGE=YES TOC_DATA;
title j=r "Page(*ESC*){thispage}";
PROC REPORT DATA=AAA(obs=100);

Ksharp_2-1741857736501.png

Ksharp_3-1741857754766.png

 

 

About your last question, I have no idea. Maybe  @Cynthia_sas  would give you a hand.

 

 

Reply

sas-innovate-white.png

Register Today!

Join us for SAS Innovate 2025, our biggest and most exciting global event of the year, in Orlando, FL, from May 6-9.

 

Early bird rate extended! Save $200 when you sign up by March 31.

Register now!

How to Concatenate Values

Learn how use the CAT functions in SAS to join values from multiple variables into a single value.

Watch How to Concatenate Values on YouTube

Find more tutorials on the SAS Users YouTube channel.

SAS Training: Just a Click Away

 Ready to level-up your skills? Choose your own adventure.

Browse our catalog!

Discussion stats
  • 24 replies
  • 2 weeks ago
  • 1014 views
  • 12 likes
  • 4 in conversation