Feeding the top 25 diagnoses into the next program

[hein68]

I have code like this (see below) where I get the top 25 diagnoses:

proc freq data=&dataems order=freq;
    tables diag1CCS/noprint out=counts;
 run;

data state;
   set counts (obs=25);
   drop percent;
run;

Then I want to write another program to go back to my original data (&dataems) and keep only the records with the top 25 diag1ccs categories.  How could I do that without having to copy and paste the top 25 diag1ccs categories into another data step?  I want a more automated process, because I will end up having to do this over 100 times.

Thanks for your help.

[GPatel]

Please refer to following two papers :

https://support.sas.com/resources/papers/proceedings/proceedings/sugi31/249-31.pdf 

https://support.sas.com/resources/papers/proceedings/proceedings/sugi30/001-30.pdf

[PaigeMiller · Accepted solution]

---

@hein68 wrote:

I have code like this (see below) where I get the top 25 diagnoses:

proc freq data=&dataems order=freq;
    tables diag1CCS/noprint out=counts;
 run;

data state;
   set counts (obs=25);
   drop percent;
run;

Then I want to write another program to go back to my original data (&dataems) and keep only the records with the top 25 diag1ccs categories.  How could I do that without having to copy and paste the top 25 diag1ccs categories into another data step?  I want a more automated process, because I will end up having to do this over 100 times.

Thanks for your help.

---

How about PROC SQL

proc sql;
    create table new as select * from &dataems 
        where diag1ccs in (Select distinct diag1ccs from state);
quit;

[hein68]

This is great!  Thanks!!

[Reeza]

Is diagnosis a single file or do you need to search all 25 (usual number) of diagnosis fields?

---

@hein68 wrote:

I have code like this (see below) where I get the top 25 diagnoses:

proc freq data=&dataems order=freq;
    tables diag1CCS/noprint out=counts;
 run;

data state;
   set counts (obs=25);
   drop percent;
run;

Then I want to write another program to go back to my original data (&dataems) and keep only the records with the top 25 diag1ccs categories.  How could I do that without having to copy and paste the top 25 diag1ccs categories into another data step?  I want a more automated process, because I will end up having to do this over 100 times.

Thanks for your help.

---

[PGStats]

Take advantage of BY processing, instead of macro processing. It's more efficient and easier to code. Here is an example calculating the median weight of students from the top three age groups, for each sex :

proc sort data=sashelp.class out=class; 
by sex age; 
run;

proc freq data=class order=freq;
by sex;
tables age/noprint out=counts;
run;
 
data keep;
do i = 1 by 1 until(last.sex);
   set counts; by sex;
   if i <= 3 then output;
   end;
drop i percent;
run;

data select;
merge class keep(in=ok);
by sex age;
if ok;
run;

proc means data=select noprint;
by sex;
var weight;
output out=medians median=med;
run;