Error Bars for Interaction Assessment

[Madame_O]

Hello, I am looking at significant interaction and want to produce error bars in SAS. I  am using PROC LOGISTIC and I used the LRT test to determine significant interactions. I will include a sample diagram of what the graphs should look like.

proc logistic data=multi descending;
class damage(ref=first) smell(ref=first) smokeinlive(ref=first) employ(ref=first) pain(ref=first) clinicalinsomnia(ref=first) sleepquality1(ref=first) everasthma(ref=first) evercb(ref=first) evercopd(ref=first) depression(ref=first) everptsd(ref=first)/param=reference;
model everanxiety=damage smell smokeinlive employ clinicalinsomnia sleepquality1 pain everasthma evercb evercopd depression everptsd employ*sleepquality1 smokeinlive*sleepquality1;
run;

[Rick_SAS · Accepted solution]

One way to do this is to use the EFFECTPLOT statement and ask for an interaction plot. Notice that since you have more than two explanatory variables, you must specify values for the variables that do not appear in the plot. There are several ways to do this, but PROC PLM will choose the reference values by default, which is probably what you want. 

Since I don't have your data, here is an example that shows how to get the plot for some data in the Sashelp.cars data set:

data cars;
set sashelp.cars;
Y = (origin='Asia');   /* make binary response var */
if type not in ('Hybrid','Truck') AND cylinders in (4,6);
run;

proc logistic data=cars descending;
class Type(ref=first) Cylinders(ref=first) DriveTrain(ref=first) / param=reference;
model Y = Type Cylinders DriveTrain Type*Cylinders;
store logiModel;
run;

/* plot interactions. See
   https://blogs.sas.com/content/iml/2019/05/30/visualize-interaction-effects-regression.html
*/
proc plm restore=logiModel noinfo;
   effectplot interaction(x=Type sliceby=DriveTrain) / cluster clm connect; 
run;

 

If you don't want the default choices for the other explanatory variables, you can use the AT= option to override the default:

proc plm restore=logiModel noinfo;
   effectplot interaction(x=Type sliceby=DriveTrain) / at(Cylinders='6') cluster clm connect; 
run;

For more information about the EFFECTPLOT and PROC PLM, see

• Use the EFFECTPLOT statement to visualize regression models in SAS - The DO Loop
• Visualize multivariate regression models by slicing continuous variables - The DO Loop (sas.com)
• Visualize interaction effects in regression models - The DO Loop (sas.com)

[Madame_O]

Sorry for the late response, I was able to figure it out before anyone saw the post. But thank you so much!