So the goal is to convert a useful format (one that actually shows the underlying value) into a less useful format?
Why not just leave the code alone and modify the format it creates? Whether or not that works in your case depends on what other code is in the program file. If all it is doing is creating the format, but not actually producing any printouts using the format then that would work fine.
Also why not modify the program that is generating that program to not include the value in the label?
To read a file and modify it use a simple data step. For this problem I would hunt for the beginning of the VALUE statement and then modify lines until the end of the value statement is found.
First let's make an example file from your given input:
filename in temp;
options parmcards=in;
parmcards4;
header stuff
VALUE TED_DONOR
.B = 'Unknown'
.C = 'Not answ/Inconsist'
1 = '1 HLA-identical sibling'
2 = '2 Syngeneic'
3 = '3 Related Donor, match status unknown'
4 = '4 Matched Unrelated Donor (MUD)'
31 = '31 HLA-matched other relative'
32 = '32 HLA-mismatched relative'
41 = '41 HLA matched unrelated'
42 = '42 HLA mismatched unrelated'
;
trailer stuff
;;;;
Now we can read that IN file and write to an OUT file.
For testing let's write to a temporary file also.
filename out temp;
data _null_;
infile in truncover dsd dlm=' ' end=eof;
file out ;
length x1-x3 $200 ;
input x1-x3 ;
if found then do;
if x1=';' and x2=' ' then found=0;
else do;
x4 = scan(x3,1,' ');
if not missing(input(x4,??32.)) then do;
x3=left(substrn(x3,length(x4)+1));
_infile_=catx(' ',x1,x2,quote(trim(x3),"'"));
end;
end;
end;
else if x1='VALUE' and x2='TED_DONOR' then found=1;
retain found;
put _infile_;
run;
So running this we get a log like this
NOTE: The infile IN is:
Filename=...\#LN00060,
RECFM=V,LRECL=32767,File Size (bytes)=380,
Last Modified=25Aug2022:16:27:35,
Create Time=25Aug2022:16:27:35
NOTE: The file OUT is:
Filename=...\#LN00061,
RECFM=V,LRECL=32767,File Size (bytes)=0,
Last Modified=25Aug2022:16:27:35,
Create Time=25Aug2022:16:27:35
NOTE: 18 records were read from the infile IN.
The minimum record length was 0.
The maximum record length was 43.
NOTE: 18 records were written to the file OUT.
The minimum record length was 0.
The maximum record length was 41.
NOTE: DATA statement used (Total process time):
real time 0.00 seconds
cpu time 0.01 seconds
Let's look at the results:
12 data _null_;
513 infile out;
514 input;
515 put _infile_;
516 run;
NOTE: The infile OUT is:
Filename=...\#LN00061,
RECFM=V,LRECL=32767,File Size (bytes)=356,
Last Modified=25Aug2022:16:27:35,
Create Time=25Aug2022:16:27:35
header stuff
VALUE TED_DONOR
.B = 'Unknown'
.C = 'Not answ/Inconsist'
1 = 'HLA-identical sibling'
2 = 'Syngeneic'
3 = 'Related Donor, match status unknown'
4 = 'Matched Unrelated Donor (MUD)'
31 = 'HLA-matched other relative'
32 = 'HLA-mismatched relative'
41 = 'HLA matched unrelated'
42 = 'HLA mismatched unrelated'
;
trailer stuff
NOTE: 18 records were read from the infile OUT.
The minimum record length was 0.
The maximum record length was 41.
NOTE: DATA statement used (Total process time):
real time 0.00 seconds
cpu time 0.01 seconds
