With some invaluable assistance from DLing and Tom I was able to solve the problem. The "almost" final code is shown below. The code searches a directory for all JPG files and then outputs a file called "want" that contains the file names, coordinates where each picture was taken, the dates the pictures were taken, the titles that were assigned to the pictures, and the picures' heights and widths:
%let path=c:\art\;
options datestyle=ymd;
proc format;
value ttwo 18761='pibr2.'
19789='s370fpib2.';
value tfour 18761='pibr4.'
19789='s370fpib4.';
run;
filename indata pipe "dir &path.*.jpg /b";
data want (keep=picture dt_taken coordinatesn title
width height);
length fil2read title $80;
retain _exif_pattern_num _dt_pattern_num;
format dt_taken datetime19.;
format lat lon $1.;
length coordinates $35;
infile indata truncover;
if _n_ = 1 then _exif_pattern_num=
PRXPARSE("/\x45\x78\x69\x66/");
informat f2r $50.;
input f2r;
fil2read="&path."||f2r;
done=0;
infile dummy filevar=fil2read RECFM=n lrecl=12000
end=done;
picture=fil2read;
do while(not done);
input VAR1 $char12000.;
POSITIONX = PRXMATCH(_EXIF_PATTERN_NUM,var1)+6;
endian2=put(input(substr(var1,positionx,2),pibr2.),ttwo.);
endian4=put(input(substr(var1,positionx,2),pibr2.),tfour.);
numberx=inputn(substr(var1,positionx+inputn(substr(
var1,positionx+4,4),endian4),2),endian2);
offset=positionx+inputn(substr(var1,positionx+4,4),
endian4)+2;
gps_offset=0;
subject_offset=0;
date_offset=0;
last_offset=0;
do i=0 to numberx-1;
xtag=inputn(substr(var1,offset+i*12,2),endian2);
if xtag eq 34853 then do;
gps_bytes=inputn(substr(var1,offset+i*12+2,2),
endian2);
if gps_bytes eq 2 then gps_offset=positionx+
inputn(substr(var1,offset+i*12+10,2),endian2);
else gps_offset=positionx+
inputn(substr(var1,offset+i*12+8,4),endian4);
end;
else if xtag eq 40091 then do;
title_offset=positionx+inputn(substr(
var1,offset+i*12+8,4),endian4);
title_length=inputn(substr(
var1,offset+i*12+4,4),endian4);
end;
if i eq numberx-1 then do;
last_offset=positionx+inputn(substr(
var1,offset+i*12+8,4),endian4);
last_length=inputn(substr(
var1,offset+i*12+4,4),endian4);
numberx2=inputn(substr(var1,last_offset+last_length,
2),endian2);
last_offset+(last_length+2);
end;
end;
if last_offset then do;
do i=0 to numberx2-1;
xtag=inputn(substr(var1,last_offset+i*12,2),endian2);
if xtag eq 36867 then date_offset=
inputn(substr(
var1,last_offset+i*12+8,4),endian4);
else if xtag eq 40962 then width=
inputn(substr(
var1,last_offset+i*12+8,4),endian4);
else if xtag eq 40963 then height=
inputn(substr(
var1,last_offset+i*12+8,4),endian4);
end;
end;
if title_offset then title=compress(input(substr(
var1,title_offset,title_length),$50.),
"/ ?+#$%&","knp");
else title="No Title";
if gps_offset then do;
numberx=inputn(substr(var1,gps_offset,2),endian2);
offset=gps_offset+2;
do i=0 to numberx-1;
xtag=inputn(substr(var1,offset+i*12,2),endian2);
if xtag eq 1 then lat=input(substr(
var1,offset+i*12+8,1),$1.);
else if xtag eq 2 then do;
lat_offset=positionx+inputn(substr(var1,
offset+i*12+8,2),endian4);
latdeg=inputn(substr(var1,lat_offset+ 0,4),endian4)/
inputn(substr(var1,lat_offset+ 4,4),endian4);
latmin=inputn(substr(var1,lat_offset+ 8,4),endian4)/
inputn(substr(var1,lat_offset+12,4),endian4);
latsec=inputn(substr(var1,lat_offset+16,4),endian4)/
inputn(substr(var1,lat_offset+20,4),endian4);
end;
else if xtag eq 3 then lon=input(substr(
var1,offset+i*12+8,1),$1.);
else if xtag eq 4 then do;
lon_offset=positionx+inputn(substr(var1,
offset+i*12+8,2),endian4);
londeg=inputn(substr(var1,lon_offset+ 0,4),endian4)/
inputn(substr(var1,lon_offset+ 4,4),endian4);
lonmin=inputn(substr(var1,lon_offset+ 8,4),endian4)/
inputn(substr(var1,lon_offset+12,4),endian4);
lonsec=inputn(substr(var1,lon_offset+16,4),endian4)/
inputn(substr(var1,lon_offset+20,4),endian4);
end;
end;
coordinates=strip(put(latdeg,best12.))||" "||
strip(put(latmin,best12.))||"' "||
strip(put(latsec,best12.))||'" '||
strip(lat)||","||
strip(put(londeg,best12.))||" "||
strip(put(lonmin,best12.))||"' "||
strip(put(lonsec,best12.))||'" '||
strip(lon);
end;
else coordinates="No GPS";
if date_offset then dt_taken=
input(substr(var1,positionx+date_offset,19),anydtdtm19.);
else dt_taken=0;
output;
done=1;
end;
run;
