Datetime informat

[buddha_d]

SAS community,
Input is like this
16JUN16:10:30:55 (properties: Length 8, Type Numeric, format datetime16.)


Output should look like
6/16/2016 10:30:55 AM (properties: length 22, Type character, don't know format & informants for this).

I tried proc format with picture (was suggested by ballardw, worked with windows sas, but this stupid saseg is giving error that it doesn't recognize anydtdtm. Informat).

SAS gurus please help.

[art297 · Accepted solution]

Don't know why your code that runs in base wouldn't run in EG. However, the following should work in both:

data have;
  input dt datetime18.;
  format dt datetime18.;
  cards;
16JUN16:10:30:55
;

proc format library=work;
  picture Exceldt (default=22)
  low-high = '%0m/%0d/%Y %h:%0M:%0S %p' (datatype=datetime);
run;

data want;
  set have;
  char_dt=put(dt,Exceldt.);
run;

Art, CEO, AnalystFinder.com

[kiranv_]

this should do

proc format;

picture mydate other='%0m/%0d/%0Y %0H:%0M:%0S %p' (datatype=datetime);

run;

data a;

a= '16JUN16:10:30:55';

b= input(a, datetime.);

format b mydate.;

run;

[buddha_d]

Thanks Art, it worked finally. I appreciate your prompt response. Thank you