Data Saparation

[Son_Of_Krypton]

I have a table which contains  both character and numeric values and I want character values in one table and numeric values in another table how to do this.??

[PeterClemmensen]

Do something like this

data have;
input Char1 $ Char2 $ Num1 Num2;
datalines;
ten twenty 10 20
thirty forty 30 40
fifty sixty 50 60
;

proc sql noprint;
    select name into :charVars separated by " " from dictionary.columns 
    where libname="WORK" and memtype="DATA" and memname="HAVE" and type="char";
    select name into :numVars separated by " " from dictionary.columns 
    where libname="WORK" and memtype="DATA" and memname="HAVE" and type="num";
quit;

%put &charVars.;
%put &numVars.;

data CharacterVars;
    set have;
    keep &charVars.;
run;

data NumericVars;
    set have;
    keep &numVars.;
run;

[Son_Of_Krypton]

can we do this in data step without using macros.?? 

[Ksharp]

data CharacterVars;
    set have;
    keep _numeric_;
run;

data NumericVars;
    set have;
    keep _character_;
run;

[ChrisNZ · Accepted solution]

data N(keep=_NUMERIC_) 
     C(keep=_CHARACTER_);
  set SASHELP.CLASS;
run;

[Son_Of_Krypton]

Thanks for the solution

[RW9]

Whilst you have the answer, I would ask why you want to do this?  I suspect you want to do some procedure on just num vars or something like that, in which case you don't need to.  You can use the automatic _numeric_ and _character_ to refere to either blocks pretty much anywhere, e.g.:

proc means data=have;
  var _numeric_;
run;

No need to split.