Creating a new variable for a SQL table

[stephanicurry]

Hey everyone! I succesfully created a SAS table with the code below but what I need/want to do now is add another column/variable that is equal to variables One - Two. Help please!

proc sql;
create table work.combined as

select
a. Number,
a. County,
a. Counts,
a. Sickness,
a. One,
a. OverallSickness,
b. Number,
b. Two

from
today a,
yesterday b

where
a.Number = b.Number;
quit;

[Tom]

In general you don't add variables to an existing dataset.

Just make a new dataset. Simple in regular SAS code.

data new_table;
  set combined;
  new_var=one-two;
run;

Or if you want to stick with SQL syntax.

proc sql;
create table new_table as
  select *,one-two as new_var
  from combined
;
quit;

Or just make it when you make the dataset.

proc sql;
create table work.combined as
select
 a.Number
,a.County
,a.Counts
,a.Sickness
,a.One
,a.OverallSickness
,b.Number
,b.Two
,a.One - b.Two as new_var
from today a
   , yesterday b
where a.Number = b.Number
;
quit;

[stephanicurry]

Thanks so much! This was exactly what I needed 🙂