Create separate rows based on the second/ third space

[Feyng819]

For example I have the data:
data have;
input name$;
cards;
Aaron Smith Andrew Knoi
Linda Jackson Betty Young
;
run;

I want to create separate rows based on the second space like the data in the following.
data want;
input name$;
cards;
Aaron Smith
Andrew Knoi
Linda Jackson
Betty Young
;
run;

How can create separate rows based on the second space? I tried to use scan but it seems to be only working for the first space. Thank you!

[Kurt_Bremser · Accepted solution]

Loop through the string, incrementing the loop counter by 2:

data have;
input name $80.;
cards;
Aaron Smith Andrew Knoi
Linda Jackson Betty Young
;

data want;
set have;
i = 1;
word = scan(name,i);
do while(word ne "");
  n_name = catx(" ",scan(name,i),scan(name,i+1));
  output;
  i = i + 2;
  word = scan(name,i);
end;
keep n_name;
rename n_name=name;
run;

[Feyng819]

This works great! Thank you

[Astounding]

It's actually easier if you create two variables instead of one:

data have;
  length first_name last_name $ 20;
  input first_name last_name @@;
cards;
Aaron Smith Andrew Knoi
Linda Jackson Betty Young
;

[andreas_lds]

Can you add an example showing what should happen if the value has to separated at the third space?

[Ksharp]

data have;
input name $40.;
cards;
Aaron Smith Andrew Knoi
Linda Jackson Betty Young
;
run;

data want;
 set have;
 call scan(name,2,p,l,' ');
 new_name=left(substr(name,1,p+l));output;
 new_name=left(substr(name,p+l));output;
 drop p l;
run;