Create an Array of Max of an Array

[sas51]

Hi all,
I have an array of variables, i.e. Age1, Age2 ... Age144 (numeric) a MEMBERNM (character) and a family name variable FAMILYNM (character).

The age has 144 fields because it represents 144 yearly positions captured.

The data looks something like this
FAMILYNM MEMBERNM AGE1 AGE2 ...
SMITH JOHN 1 2 ...
SMITH MARY 5 6 ...
SWIFT TAYLOR 4 5 ...
SWIFT MEGAN 1 2

I would like to create an array of variables (MAXAGE1 MAXAGE2 ... MAXAGE144) which gives me the maximum age of every family, hence output should be,
FAMILYNM MEMBERNM AGE1 AGE2 ... MAXAGE1 MAXAGE2 ...
SMITH JOHN 1 2 ... 5 6
SMITH MARY 5 6 ... 5 6
SWIFT TAYLOR 4 5 ... 4 5
SWIFT MEGAN 1 2 ... 4 5

Appreciate the kind assistance.

[s_lassen · Accepted solution]

Something like this, I suppose:

Data want;                                                                                                                              
  do until(last.familynm);                                                                                                              
    set have;                                                                                                                           
    by familynm;                                                                                                                        
    array ages(*) age1-age144;                                                                                                          
    array maxage(*) 8 maxage1-maxage144;                                                                                                
    do _N_=1 to dim(ages);                                                                                                              
      maxage(_N_)=max(maxage(_N_),ages(_N_));                                                                                           
      end;                                                                                                                              
    end;                                                                                                                                
  do until(last.familynm);                                                                                                              
    set have;                                                                                                                           
    by familynm;                                                                                                                        
    output;                                                                                                                             
    end;                                                                                                                                
run;         

[ballardw]

This seems like you may be attempting to force a spreadsheet style of solution onto a SAS data set.

How do you expect to use that result?