Count presence of two-character string among many characters

[brulard]

hi,

I need to count times string "RE" appears in multicharacter string. String is always char.

Example:

Data_Want     Column_have_id     Column_have_string

2                               01                   NDCSPCRCBCSLAFDWIWOFDSPDERRDETDRECADETDRECA

1                               02                   ENDCSPCRCBCSLAFDWIWOFDSPDERRDETDRECADETD

1                               03                   ENDCSPCRCBCSLAFDWIWOFDSPDERRDETDRECADETD

0                               04                   ENDCSPCRCBCSLAFDWIWOFDSP

In the first string of data in the above example, "RE" is read twice. ("RE" should be captured as is, not "ER"...).

thank you

[RW9 · Accepted solution]

Just loop over the characters 1 by 1, and if char + 1 = RE increment count:

data have;
  length s $2000;
  input s $;
datalines; 
NDCSPCRCBCSLAFDWIWOFDSPDERRDETDRECADETDRECA
ENDCSPCRCBCSLAFDWIWOFDSPDERRDETDRECADETD
;
run;

data want (drop=i);
  set have;
  count=0;
  do i=1 to lengthn(s)-1;
    if cats(char(s,i),char(s,i+1))="RE" then count=sum(count,1);
  end;
run;

[brulard]

this is very helpful, thanks again

[data_null__]

---

@brulard wrote:

hi,

I need to count times string "RE" appears in multicharacter string. String is always char.

Example:

Data_Want     Column_have_id     Column_have_string

2                               01                   NDCSPCRCBCSLAFDWIWOFDSPDERRDETDRECADETDRECA

1                               02                   ENDCSPCRCBCSLAFDWIWOFDSPDERRDETDRECADETD

1                               03                   ENDCSPCRCBCSLAFDWIWOFDSPDERRDETDRECADETD

0                               04                   ENDCSPCRCBCSLAFDWIWOFDSP

In the first string of data in the above example, "RE" is read twice. ("RE" should be captured as is, not "ER"...).

thank you

---

The FIND function is a good choice for this problem.

data re;
   input s $80.;
   count=0;
   do x=1 by 0 until(f eq 0);
      f=find(s,'RE',x);
      if f then count+1;
      x=f+2;
      end;
   drop x f;
   cards;
NDCSPCRCBCSLAFDWIWOFDSPDERRDETDRECADETDRECA
ENDCSPCRCBCSLAFDWIWOFDSPDERRDETDRECADETD
ENDCSPCRCBCSLAFDWIWOFDSPDERRDETDRECADETD
ENDCSPCRCBCSLAFDWIWOFDSP
;;;;
   run;
proc print;
   run;

[Ksharp]

Can you use COUNT()?


data have;
  length s $2000;
  input s $;
datalines; 
NDCSPCRCBCSLAFDWIWOFDSPDERRDETDRECADETDRECA
ENDCSPCRCBCSLAFDWIWOFDSPDERRDETDRECADETD
;
run;

data want (drop=i);
  set have;
  count=0;
  do i=1 to lengthn(s)-1;
    if cats(char(s,i),char(s,i+1))="RE" then count=sum(count,1);
  end;
  
  c=count(s,'RE');
  
run;
proc print;run;

[brulard]

that works too. Thanks Ksharp