The key to show a value that has been assigned a numeric value is custom format such as:
Proc format;
value yesno
1 = 'Yes'
0 = 'No'
;
run;
And then associate the format with a variable that takes numeric values of 0 and 1.
A similar INVALUE statement can create a numeric value when reading a variable.
So the tasks involved are
1) getting UNIQUE values
2) decide on format VALUE and INVALUE names (31 character limit for character variables as you need a $ in the name )
3) create the formats. Proc Format can use a specially structured data set to create a format so creating that set
4) use a data step to build a new dataset with the numeric variables and assign the formats.
Here is an example using a data set you should have available as a start.
data junk;
set sashelp.class ;
array c _character_;
length vn $ 32. val $ 100;
do i= 1 to dim(c);
vn=vname(c[i]);
val = upcase(c[i]);
vl = vlength(c[i]);
output;
end;
keep vn val vl;
run;
proc sql;
create table use as
select distinct vn, val, vl
from junk
order by vn, val;
run;
/* create a data set with numeric values from 1 to n for each
unique value of the variable by name
*/
data makefmts;
set use;
by vn;
retain num;
if first.vn then num=1 ;
else num+1;
run;
data cntlin;
set makefmts;
length fmtname $ 32 start label $ 100 hlo $ 3;
fmtname=vn;
/* characteristics of the informat*/
type='I' ;
start = upcase(strip(val));
label= strip(put(num,best5.));
hlo='U';
output;
/* characteristics of the FORMAT*/
type='N';
start= strip(put(num,best5.));
label= upcase(strip(val));
default=vl;
output;
run;
proc sort data=cntlin;
by fmtname type num;
run;
proc format library=work cntlin=cntlin cntlout=work.cntlout;
run;
data work.newclass;
set sashelp.class;
numname = input(name,name.);
numsex = input(sex,sex.);
format numname name. numsex sex.;
run;
Warnings:
If you keep adding values there is no guarantee that a specific value will maintain the same numeric value. You likely should place the CNTLIN and generated CNTLOUT data sets in permanent library.
If you add variables then you have another start from scratch scenario.
Note that the SORTED order of the CNTLIN data set is very critical.
This uses the name of the variable to create both and informat and format with the same name. If you already have such then you may need to play around with the FMTSEARCH system option and where to place the results of this Proc Format code.
All of the character values will be treated in uppercase. If this is not acceptable then you will need to write a lot of manual code. The purpose of the uppercase options are so that values like "UNITED ARAB EMIRATES" "United Arab Emirates" and "united arab emirates" all would get the same numeric value. If you want the same spelling but different combinations of upper and lower case to get different numeric values you are on your own as there are obviously many more rules involved than you have specified.
The length for VAL in the first data step should be length of the longest expected value of any of the character variables. If you have some sort of open text variable that would contain a paragraph of description you should really consider if it is needed at all for whatever the process may be.
Anything involving dates will in the long run benefit from creating a actual SAS date values you can generate Month, Year, yearmonth and Qtr (assuming it is a calendar quarter) all from the single date as needed if you have that as a date value and sorting and analysis will be much cleaner. By the way a year month like 20183 will not sort properly in either numeric or character form. You would have to make sure that the months were all two digits so that 201803 comes before 201812 if character and if you use a numeric 201812 it will come after 20191.
