Convert today() in a character

[DataExplorer]

I want to convert today() in charakter.

My idea was:

%Let Mydate="put(today() date9.)" ;

But it seems I have an error in my thinking.

[gamotte · Accepted solution]

You mix up several things :

- macro instructions/functions (beginning with %)

- base sas language, data step functions.

You can use a datastep function in a macro instruction with %sysfunc.

If you want to create a variable in a dataset with today's date :

data have;
myDate=put(today(), date9.);
put myDate=;
run;

If you want to create a macrovariable instead :

%let myDate=%sysfunc(putn(%sysfunc(today()),date9.));

%put &=myDate.;

Or

data _NULL_;
myDate=put(today(), date9.);
call symputx("myDate",myDate);
run;

[VDD]

data _null_;
	date1=input(put(today(),yymmdd8.),yymmdd8.);
        put date1;
	format date1 date9.;
run;

[Astounding]

Yes, many errors. But the good news is that you don't need to do anything. There is an automatic macro variable that contains what you are trying to create: &sysdate9

[DataExplorer]

Thanks the solutions:

%let myDate=%sysfunc(putn(%sysfunc(today()),date9.));

 or 

&sysdate9

work for me.